Sql.Database

Unit
Bron
Symbols

Symbol	Description
TSqlDatabase	Abstract base class for connections to databases that can be queried using SQL statements.
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
///////////////////////////////////////////////////////////////////////////
//                                                                       //
//  Copyright (c) 2015 by Charta Software B.V.                           //
//  All rights reserved                                                  //
//                                                                       //
//  Version:  1.7.0.83525                                                //
//  Web site: https://pascal.chartasoftware.com/                         //
//                                                                       //
//  This code and information are provided "as is" without warranty of   //
//  any kind. Dissemination of this information or reproduction of       //
//  this material is strictly forbidden unless prior written permission  //
//  is obtained from Charta Software B.V..                               //
//                                                                       //
///////////////////////////////////////////////////////////////////////////

unit Sql.Database;

interface

uses
  Boolean,
  Color.Rgb,
  DateTime.Calendar.Gregorian.Date,
  DateTime.Calendar.Gregorian.Instant,
  Decimal,
  FloatingPoint._64,
  Integer,
  Integer._32.Positive,
  Sql.Connection.Settings,
  Sql.Database.PreparedStatement,
  Sql.Expression.Row,
  Sql.Result,
  Sql.Statement,
  Sql.Statement.Executor,
  Sql.Statement.ResultSet,
  Sql.Table.Column,
  Sql.Transaction,
  Stream.Input,
  Text,
  Uuid;

type
  TSqlDatabase = class(TSqlStatementExecutor)
  protected
    function    GetConnectionSettings(): TSqlConnectionSettings; virtual; abstract;
    function    GetCouldConnect(): TBoolean; virtual; abstract;

  public
    procedure   Execute(Statement: TSqlStatement); override;
    procedure   Flush(); override;

  public
    function    Query(Statement: TSqlStatement; ResultMethod: TSqlQueryResultMethod = sqrmStoreResult): TSqlResult; virtual; abstract;
    function    QuerySingleRow(Statement: TSqlStatement): TSqlResult;
    function    Prepare(Statement: TSqlStatement): TSqlPreparedStatement; virtual; abstract;

    function    StartTransaction(): TSqlTransaction; virtual; abstract;
    procedure   EndTransaction(Transaction: TSqlTransaction); virtual; abstract;

    function    ConnectionIdentifier(): TInteger; virtual; abstract;

    function    InsertId(): TInteger; virtual; abstract;
    function    NumberOfAffectedRows(): TInteger; virtual; abstract;

    function    Insert(Statement: TSqlStatement): TInteger;
    function    Exists(Statement: TSqlResultSetStatement): TBoolean;

    // TODO: Table should be a TSqlTable but currently that would introduce a circular reference
    function    SelectOrInsert(Table: TObject; const Columns: array of TSqlTableColumn; Row: TSqlRow): TInteger;

    function    SelectDecimal(Statement: TSqlResultSetStatement): TDecimal;
    function    SelectDecimalWithDefault(Statement: TSqlResultSetStatement; const DefaultValue: TDecimal): TDecimal;
    function    SelectInteger(Statement: TSqlResultSetStatement): TInteger;
    function    SelectIntegerWithDefault(Statement: TSqlResultSetStatement): TInteger; overload;
    function    SelectIntegerWithDefault(Statement: TSqlResultSetStatement; const DefaultValue: TInteger): TInteger; overload;
    function    SelectText(Statement: TSqlResultSetStatement): TText;
    function    SelectTextWithDefault(Statement: TSqlResultSetStatement): TText; overload;
    function    SelectTextWithDefault(Statement: TSqlResultSetStatement; const DefaultValue: TText): TText; overload;
    function    SelectBoolean(Statement: TSqlResultSetStatement): TBoolean;
    function    SelectBooleanWithDefault(Statement: TSqlResultSetStatement; DefaultValue: TBoolean = False): TBoolean;
    function    SelectFloatingPoint(Statement: TSqlResultSetStatement): TFloatingPoint64;
    function    SelectFloatingPointWithDefault(Statement: TSqlResultSetStatement; DefaultValue: TFloatingPoint64 = 0): TFloatingPoint64;
    function    SelectDate(Statement: TSqlResultSetStatement): TGregorianDate;
    function    SelectInstant(Statement: TSqlResultSetStatement): TGregorianInstant;
    function    SelectColor(Statement: TSqlResultSetStatement): TRgbColor;
    function    SelectColorWithDefault(Statement: TSqlResultSetStatement; const DefaultValue: TRgbColor): TRgbColor;
    function    SelectUuid(Statement: TSqlResultSetStatement): TUuid;
    function    SelectUuidWithDefault(Statement: TSqlResultSetStatement; const DefaultValue: TUuid): TUuid;
    function    SelectStream(Statement: TSqlStatement): TInputStream;

    function    IsAlive(): TBoolean; virtual; abstract;
    function    IdleTime(): TPositiveInteger32; virtual; abstract;
    function    UserExists(const Name: TText): TBoolean; virtual; abstract;

    function    TableExists(const Name: TText): TBoolean; virtual; // TODO: Instead of a TableName we should provide a TSqlTable, however, currently this would introduce a circular unit reference
    function    TableHasConstraint(const Table: TText; const Constraint: TText): TBoolean; virtual;
    function    CreateTableDefinition(const SchemaName: TText; const TableName: TText): TObject; // TODO: Instead of a TObject we should return a TSqlTable, however, currently this would introduce a circular unit reference

    // TODO: We return a TObject which actually is a TSqlSystemInformation to prevent circular unit references
    function    GetSystemInformation(): TObject; virtual; abstract;

    function    Embellish(): TSqlDatabase; virtual;

    property    ConnectionSettings: TSqlConnectionSettings read GetConnectionSettings;
    property    CouldConnect: TBoolean read GetCouldConnect;
  end;

implementation

uses
  Byte.Block,
  FloatingPoint.Type_,
  Integer._32,
  Integer._32.TextFormat,
  Integer.Type_,
  Sql,
  Sql.Database.PreparedStatement.Stream,
  Sql.Database.SystemInformation,
  Sql.Exception,
  Sql.Operator_.Binary,
  Sql.Schema.Information,
  Sql.Statement.DataManipulation,
  Sql.Statement.ResultSet.Select,
  Sql.Table,
  Sql.Table.Column.Reference,
  Sql.Table.Index.Column,
  Sql.Table.Physical,
  StructuredDocument.Node.Text,
  Text.Type_,
  Type_,
  Type_.System;

{ TSqlDatabase }

function TSqlDatabase.CreateTableDefinition(const SchemaName: TText; const TableName: TText): TObject;
var
  Table:                 TSqlPhysicalTable;
  InformationSchema:     TSqlInformationSchema;
  ColumnsTable:          TSqlColumnsTable;
  SqlResult:             TSqlResult;
  ColumnName:            TText;
  ColumnType:            TText;
  Type_:                 TType;
  KeyColumnUsageTable:   TSqlKeyColumnUsageTable;
  TableConstraintsTable: TSqlTableConstraintsTable;
  PrimaryKey:            array of TSqlTableIndexColumn;
  KeyColumn:             TSqlTableIndexColumn;
  i:                     TInteger32;
begin
  InformationSchema := (GetSystemInformation() as TSqlSystemInformation).GetInformationSchema();
  ColumnsTable      := InformationSchema.Columns;
  Table             := TSqlPhysicalTable.Create(TableName);

  SqlResult := Query(SelectGroupedOrderBy(
    [ ColumnsTable.ColumnName, ColumnsTable.DataType ],
    [ ColumnsTable ],
    [
      ColumnsTable.TableName = TableName,
      ColumnsTable.TableSchema = SchemaName
    ],
    [],
    [ ColumnsTable.OrdinalPosition ]
  ));

  while SqlResult.FetchRow() do
  begin
    ColumnName := SqlResult.ReadText();
    ColumnType := SqlResult.ReadText().ToLowerCase();

    if ColumnType = 'int' then
      Type_ := TBoundedIntegerType._32
    else if ColumnType = 'double' then
      Type_ := TFloatingPointType._64
    else if ColumnType = 'datetime' then
      Type_ := DDateTime
    else
      Type_ := TTextType.Long;

    Table.CreateColumn(ColumnName, TDocumentText.Create(ColumnName), Type_);
  end;

  SqlResult.Free();

  KeyColumnUsageTable   := InformationSchema.KeyColumnUsage;
  TableConstraintsTable := InformationSchema.TableConstraints;

  SqlResult := Query(SelectGroupedOrderBy(
    [ KeyColumnUsageTable.ColumnName ],
    [ KeyColumnUsageTable, TableConstraintsTable ],
    [
      TableConstraintsTable.TableSchema = SchemaName,
      TableConstraintsTable.TableName = TableName,
      TableConstraintsTable.ConstraintType = TableConstraintsTable.CONSTRAINT_PRIMARY_KEY,
      KeyColumnUsageTable.ConstraintName = TableConstraintsTable.ConstraintName,
      KeyColumnUsageTable.TableSchema = SchemaName,
      KeyColumnUsageTable.TableName = TableName
    ],
    [],
    [ KeyColumnUsageTable.OrdinalPosition ]
  ));

  SetLength(PrimaryKey, SqlResult.GetRowCount());

  for i := 0 to High(PrimaryKey) do
  begin
    SqlResult.FetchRow();
    ColumnName := SqlResult.ReadText();

    KeyColumn := TSqlTableIndexColumn.Create();
    KeyColumn.Column := Table.Columns.Find(TSqlTableColumn.THasIdentifier.Create(ColumnName));

    PrimaryKey[i] := KeyColumn;
  end;

  if System.Length(PrimaryKey) > 0 then
    Table.SetPrimaryKey(PrimaryKey);

  SqlResult.Free();
  Result := Table;
end;

function TSqlDatabase.Embellish(): TSqlDatabase;
begin
  Result := Self;
end;

procedure TSqlDatabase.Execute(Statement: TSqlStatement);
begin
  Query(Statement).Free();
end;

function TSqlDatabase.Exists(Statement: TSqlResultSetStatement): TBoolean;
begin
  Result := SelectBoolean(Select([Sql.Exists(Statement)], [], []));
end;

procedure TSqlDatabase.Flush();
begin
end;

function TSqlDatabase.Insert(Statement: TSqlStatement): TInteger;
begin
  Query(Statement);
  Result := InsertId;
end;

function TSqlDatabase.QuerySingleRow(Statement: TSqlStatement): TSqlResult;
begin
  Result := Query(Statement);

  if Result.GetRowCount() = 1 then
    Result.FetchRow()
  else
    raise ESql.Create('Exactly one row expected but found: ' + Integer32ToText(Result.GetRowCount()));
end;

function TSqlDatabase.SelectBoolean(Statement: TSqlResultSetStatement): TBoolean;
var
  SqlResult: TSqlResult;
begin
  SqlResult := Query(Statement);
  SqlResult.FetchRow();

  Result := SqlResult.ReadBoolean();
  SqlResult.Free();
end;

function TSqlDatabase.SelectBooleanWithDefault(Statement: TSqlResultSetStatement; DefaultValue: TBoolean): TBoolean;
var
  SqlResult: TSqlResult;
begin
  SqlResult := Query(Statement);

  if SqlResult.FetchRow() then
    Result := SqlResult.ReadBoolean()
  else
    Result := DefaultValue;

  SqlResult.Free();
end;

function TSqlDatabase.SelectColor(Statement: TSqlResultSetStatement): TRgbColor;
var
  SqlResult: TSqlResult;
begin
  SqlResult := Query(Statement);
  SqlResult.FetchRow();
  
  Result := SqlResult.ReadColor();
  SqlResult.Free();
end;

function TSqlDatabase.SelectColorWithDefault(Statement: TSqlResultSetStatement; const DefaultValue: TRgbColor): TRgbColor;
var
  SqlResult: TSqlResult;
begin
  SqlResult := Query(Statement);

  if SqlResult.FetchRow() then
    Result := SqlResult.ReadColor()
  else
    Result := DefaultValue;

  SqlResult.Free();
end;

function TSqlDatabase.SelectDate(Statement: TSqlResultSetStatement): TGregorianDate;
var
  SqlResult: TSqlResult;
begin
  SqlResult := Query(Statement);
  SqlResult.FetchRow();

  Result := SqlResult.ReadDate();
  SqlResult.Free();
end;

function TSqlDatabase.SelectDecimal(Statement: TSqlResultSetStatement): TDecimal;
var
  SqlResult: TSqlResult;
begin
  SqlResult := Query(Statement);
  SqlResult.FetchRow();

  Result := SqlResult.ReadDecimal();
  SqlResult.Free();
end;

function TSqlDatabase.SelectDecimalWithDefault(Statement: TSqlResultSetStatement; const DefaultValue: TDecimal): TDecimal;
var
  SqlResult: TSqlResult;
begin
  SqlResult := Query(Statement);

  if SqlResult.FetchRow() then
    Result := SqlResult.ReadDecimal
  else
    Result := DefaultValue;

  SqlResult.Free();
end;

function TSqlDatabase.SelectFloatingPoint(Statement: TSqlResultSetStatement): TFloatingPoint64;
var
  SqlResult: TSqlResult;
begin
  SqlResult := Query(Statement);
  SqlResult.FetchRow();

  Result := SqlResult.ReadFloatingPoint();
  SqlResult.Free();
end;

function TSqlDatabase.SelectFloatingPointWithDefault(Statement: TSqlResultSetStatement; DefaultValue: TFloatingPoint64): TFloatingPoint64;
var
  SqlResult: TSqlResult;
begin
  SqlResult := Query(Statement);

  if SqlResult.FetchRow() then
    Result := SqlResult.ReadFloatingPoint()
  else
    Result := DefaultValue;

  SqlResult.Free();
end;

function TSqlDatabase.SelectInstant(Statement: TSqlResultSetStatement): TGregorianInstant;
var
  SqlResult: TSqlResult;
begin
  SqlResult := Query(Statement);
  SqlResult.FetchRow();

  Result := SqlResult.ReadInstant();
  Result.AddReference();

  SqlResult.Free();
  Result.DiscardReference();
end;

function TSqlDatabase.SelectInteger(Statement: TSqlResultSetStatement): TInteger;
var
  SqlResult: TSqlResult;
begin
  SqlResult := Query(Statement);
  SqlResult.FetchRow();

  Result := SqlResult.ReadInteger();
  SqlResult.Free();
end;

function TSqlDatabase.SelectIntegerWithDefault(Statement: TSqlResultSetStatement): TInteger;
begin
  Result := SelectIntegerWithDefault(Statement, 0);
end;

function TSqlDatabase.SelectIntegerWithDefault(Statement: TSqlResultSetStatement; const DefaultValue: TInteger): TInteger;
var
  SqlResult: TSqlResult;
begin
  SqlResult := Query(Statement);

  if SqlResult.FetchRow() then
    Result := SqlResult.ReadInteger()
  else
    Result := DefaultValue;

  SqlResult.Free();
end;

function TSqlDatabase.SelectOrInsert(Table: TObject; const Columns: array of TSqlTableColumn; Row: TSqlRow): TInteger;
var
  SqlResult:    TSqlResult;
  Select:       TSqlSelect;
  InsertValues: TSqlInsertValues;
  Index:        TInteger32;
  CastTable:    TSqlTable;
begin
  CastTable := Table as TSqlTable; // TODO: This type cast should not be necessary when we Table is declared as a proper TSqlTable
  Row.AddReference();

  try
    if CastTable.PrimaryKey.Columns.Count = 1 then
    begin
      if System.Length(Columns) = Row.Columns.Count then
      begin
        Select := TSqlSelect.Create();
        Select.From.Add(CastTable.ToExpression());
        Select.Columns.AddTableColumn(CastTable.PrimaryKey.Columns.First.Column);

        for Index := 0 to High(Columns) do
          Select.Restrictions.Add(TSqlEqual.Create(TSqlTableColumnReference.Create(Columns[Index]), Row.Columns[Index]));

        SqlResult := Query(Select);

        if SqlResult.FetchRow() then
          Result := SqlResult.ReadInteger()
        else
        begin
          InsertValues := TSqlInsertValues.Create(CastTable);
          InsertValues.Columns.AddAll(Columns);
          InsertValues.Rows.Add(Row);

          Result := Insert(InsertValues);
        end;

        SqlResult.Free();
      end
      else
        raise ESql.Create('Mismatch between columns and values');
    end
    else
      raise ESql.Create('Primary key with one integer column expected');
  finally
    Row.ReleaseReference();
  end;
end;

function TSqlDatabase.SelectStream(Statement: TSqlStatement): TInputStream;
var
  PreparedStatement: TSqlPreparedStatement;
  StatementResult:   TSqlResult;
  Stream:            TSqlPreparedStatementInputStream;
  Block:             TByteBlock;
begin
  PreparedStatement := Prepare(Statement);

  StatementResult := PreparedStatement.Execute();
  StatementResult.FetchRow();

  Block := StatementResult.ReadByteBlock();

  if Block <> nil then
  begin
    Stream := TSqlPreparedStatementInputStream.Create(Block.CreateInputStream());
    Stream.Statement       := PreparedStatement;
    Stream.StatementResult := StatementResult;
    Stream.Block           := Block;

    Result := Stream;
  end
  else
  begin
    Result := nil;

    StatementResult.Free();
    PreparedStatement.Free();
  end;
end;

function TSqlDatabase.SelectText(Statement: TSqlResultSetStatement): TText;
var
  SqlResult: TSqlResult;
begin
  SqlResult := Query(Statement);
  SqlResult.FetchRow();
  
  Result := SqlResult.ReadText();
  SqlResult.Free();
end;

function TSqlDatabase.SelectTextWithDefault(Statement: TSqlResultSetStatement): TText;
begin
  Result := SelectTextWithDefault(Statement, '');
end;

function TSqlDatabase.SelectTextWithDefault(Statement: TSqlResultSetStatement; const DefaultValue: TText): TText;
var
  SqlResult: TSqlResult;
begin
  SqlResult := Query(Statement);

  if SqlResult.FetchRow() then
    Result := SqlResult.ReadText()
  else
    Result := DefaultValue;

  SqlResult.Free();
end;

function TSqlDatabase.SelectUuid(Statement: TSqlResultSetStatement): TUuid;
var
  SqlResult: TSqlResult;
begin
  SqlResult := Query(Statement);
  SqlResult.FetchRow();

  Result := SqlResult.ReadUuid();
  SqlResult.Free();
end;

function TSqlDatabase.SelectUuidWithDefault(Statement: TSqlResultSetStatement; const DefaultValue: TUuid): TUuid;
var
  SqlResult: TSqlResult;
begin
  SqlResult := Query(Statement);

  if SqlResult.FetchRow() then
    Result := SqlResult.ReadUuid()
  else
    Result := DefaultValue;

  SqlResult.Free();
end;

function TSqlDatabase.TableExists(const Name: TText): TBoolean;
var
  TablesTable: TSqlTablesTable;
begin
  TablesTable := (GetSystemInformation() as TSqlSystemInformation).GetInformationSchema().Tables;
  Result      := Exists(Select([1], [TablesTable], [TablesTable.TableSchema = ConnectionSettings.DatabaseName, TablesTable.TableName = Name]));
end;

function TSqlDatabase.TableHasConstraint(const Table: TText; const Constraint: TText): TBoolean;
var
  ConstraintsTable: TSqlTableConstraintsTable;
begin
  ConstraintsTable := (GetSystemInformation() as TSqlSystemInformation).GetInformationSchema().TableConstraints;

  Result := Exists(
    Select(
      [ 1 ],
      [ ConstraintsTable ],
      [
        ConstraintsTable.TableSchema = ConnectionSettings.DatabaseName,
        ConstraintsTable.TableName = Table,
        ConstraintsTable.ConstraintName = Constraint
      ]
    )
  );
end;

end.