Html.Element.Block.Form

Unit
Source
Symbols

Symbol	Description
THtmlButton	Button for initiating an action
THtmlButtonType	Specified the type of button
THtmlChangeableElement	Base class for HTML input
THtmlFieldSet	A set of form controls grouped under a common name
THtmlForm	A user submittable form
THtmlFormEncodingType	Encoding types for `THtmlForm` data
THtmlInput	Form control allowing for data entry by the user
THtmlInputType	Specifies the type of input in a `THtmlInput`
THtmlLabel	A label associated with an input element
THtmlLegend	Caption for a `THtmlFieldSet`
THtmlOption	Option in a `THtmlSelect`
THtmlSelect	A control for selecting amongst a set of `THtmlOption`s
THtmlTextArea	Multiline text data
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
///////////////////////////////////////////////////////////////////////////
//                                                                       //
//  Copyright (c) 2015 by Charta Software B.V.                           //
//  All rights reserved                                                  //
//                                                                       //
//  Version:  1.7.0.83525                                                //
//  Web site: https://pascal.chartasoftware.com/                         //
//                                                                       //
//  This code and information are provided "as is" without warranty of   //
//  any kind. Dissemination of this information or reproduction of       //
//  this material is strictly forbidden unless prior written permission  //
//  is obtained from Charta Software B.V..                               //
//                                                                       //
///////////////////////////////////////////////////////////////////////////

unit Html.Element.Block.Form;

interface

uses
  Boolean,
  Collection.List,
  Html.Attribute,
  Html.Element.Container,
  Html.Element.Stylable,
  Http.Method,
  Integer._32,
  Text,
  Uri;

type
  {$SCOPEDENUMS ON}
  THtmlFormEncodingType = (UriEncoded, Multipart);

  THtmlFieldSet = class(THtmlContainerElement);
  THtmlLegend = class(THtmlContainerElement);

  THtmlForm = class(THtmlContainerElement)
  public
    Method:       THttpMethod;
    Action:       TUri;
    EncodingType: THtmlFormEncodingType;
    OnSubmit:     TText;

    procedure   AddAttributes(Attributes: THtmlAttributes); override;
  end;

  THtmlChangeableElement = class(THtmlStylableElement)
  protected
    FReadOnly: TBoolean;

    procedure  SetReadOnly(Value: TBoolean);

  public
    OnChange: TText;

    procedure   AddAttributes(Attributes: THtmlAttributes); override;

    property    ReadOnly: TBoolean read FReadOnly write SetReadOnly;
  end;

  THtmlLabel = class(THtmlContainerElement)
  public
    AccessKey: TText;
    ForValue:  TText;

    procedure   AddAttributes(Attributes: THtmlAttributes); override;
  end;

  THtmlInputType = (Submit, Text, Password, Hidden, File_, CheckBox, RadioButton, Button);

  THtmlInput = class(THtmlChangeableElement)
  protected
    function    InputTypeToText(InputType: THtmlInputType): TText;

  public
    AutoComplete: TBoolean;
    Checked:      TBoolean;
    Disabled:     TBoolean;
    InputType:    THtmlInputType;
    TabIndex:     TInteger32;
    Value:        TText;

    constructor Create(InputType: THtmlInputType); reintroduce; virtual;

    procedure   AddAttributes(Attributes: THtmlAttributes); override;
  end;

  THtmlButtonType = (Button, Reset, Submit);

  THtmlButton = class(THtmlContainerElement)
  protected
    function    ButtonTypeToText(ButtonType: THtmlButtonType): TText;

  public
    Disabled:   TBoolean;
    ButtonType: THtmlButtonType;
    Value:      TText;

    procedure   AddAttributes(Attributes: THtmlAttributes); override;
  end;

  THtmlOption = class(THtmlContainerElement)
  public
    Value:    TText;
    Selected: TBoolean;

    procedure   AddAttributes(Attributes: THtmlAttributes); override;
  end;

  THtmlSelect = class(THtmlChangeableElement)
  public
    Options:  TList<THtmlOption>;
    Size:     TInteger32;
    TabIndex: TInteger32;

    constructor Create(); override;
    destructor  Destroy(); override;

    procedure   AddAttributes(Attributes: THtmlAttributes); override;
  end;

  THtmlTextArea = class(THtmlChangeableElement)
  public
    Value:    TText;
    TabIndex: TInteger32;
    Columns:  TInteger32;
    Rows:     TInteger32;

    procedure   AddAttributes(Attributes: THtmlAttributes); override;
  end;

implementation

uses
  Exception,
  Integer._32.TextFormat,
  Object_.List,
  Object_.Reference.Counter;

{ THtmlForm }

procedure THtmlForm.AddAttributes(Attributes: THtmlAttributes);
begin
  inherited AddAttributes(Attributes);

  Attributes.AddRequired('method', Method.ToText());
  Attributes.AddOptional('action', Action.ToText());
  Attributes.AddOptional('onSubmit', OnSubmit);

  if EncodingType = THtmlFormEncodingType.Multipart then
    Attributes.AddRequired('enctype', 'multipart/form-data')
  else if EncodingType <> THtmlFormEncodingType.UriEncoded then
    raise EException.Create('Unknown form encoding type');
end;

{ THtmlInput }

procedure THtmlInput.AddAttributes(Attributes: THtmlAttributes);
begin
  inherited AddAttributes(Attributes);

  Attributes.Add(THtmlAttribute.Create('type', InputTypeToText(InputType)));

  if (InputType in [THtmlInputType.Text, THtmlInputType.Password]) and not AutoComplete then
    Attributes.AddRequired('autocomplete', 'off');

  if not (InputType in [THtmlInputType.CheckBox]) then
    Attributes.AddOptional('value', Value);

  if (InputType in [THtmlInputType.CheckBox, THtmlInputType.RadioButton]) and (Checked) then
    Attributes.AddRequired('checked', 'on');

  if TabIndex <> 0 then
    Attributes.AddRequired('tabindex', Integer32ToText(TabIndex));

  if Disabled then
    Attributes.AddRequired('disabled', Disabled);
end;

constructor THtmlInput.Create(InputType: THtmlInputType);
begin
  inherited Create();

  Self.InputType := InputType;
  AutoComplete   := True;
end;

function THtmlInput.InputTypeToText(InputType: THtmlInputType): TText;
begin
  case InputType of
    THtmlInputType.Submit:       Result := 'submit';
    THtmlInputType.Text:         Result := 'text';
    THtmlInputType.Password:     Result := 'password';
    THtmlInputType.Hidden:       Result := 'hidden';
    THtmlInputType.File_:        Result := 'file';
    THtmlInputType.CheckBox:     Result := 'checkbox';
    THtmlInputType.RadioButton:  Result := 'radio';
    THtmlInputType.Button:       Result := 'button';
    else
      Result := 'submit';
  end;
end;

{ THtmlSelect }

procedure THtmlSelect.AddAttributes(Attributes: THtmlAttributes);
begin
  inherited AddAttributes(Attributes);

  if Size <> 1 then
    Attributes.AddRequired('size', Integer32ToText(Size));

  if TabIndex <> 0 then
    Attributes.AddOptional('tabindex', Integer32ToText(TabIndex));
end;

constructor THtmlSelect.Create();
begin
  inherited Create();

  Options := TObjectList<THtmlOption>.Create();
  Options.ElementManager := TReferenceCounter<THtmlOption>.Create();

  Size     := 1;
  TabIndex := 0;
end;

destructor THtmlSelect.Destroy();
begin
  Options.Free();

  inherited Destroy();
end;

{ THtmlChangeableElement }

procedure THtmlChangeableElement.AddAttributes(Attributes: THtmlAttributes);
begin
  inherited AddAttributes(Attributes);

  Attributes.AddOptional('onchange', OnChange);
  Attributes.AddOptional('readonly', ReadOnly);
end;

procedure THtmlChangeableElement.SetReadOnly(Value: TBoolean);
begin
  if Value then
    Classes.Add('read-only')
  else
    Classes.Remove('read-only');

  FReadOnly := Value;
end;

{ THtmlOption }

procedure THtmlOption.AddAttributes(Attributes: THtmlAttributes);
begin
  inherited AddAttributes(Attributes);

  Attributes.AddRequired('value', Value);

  if Selected then
    Attributes.AddRequired('selected', 'selected');
end;

{ THtmlTextArea }

procedure THtmlTextArea.AddAttributes(Attributes: THtmlAttributes);
begin
  inherited AddAttributes(Attributes);

  if TabIndex <> 0 then
    Attributes.AddRequired('tabindex', Integer32ToText(TabIndex));

  if Rows <> 0 then
    Attributes.AddRequired('rows', Integer32ToText(Rows));

  if Columns <> 0 then
    Attributes.AddRequired('cols', Integer32ToText(Columns));
end;

{ THtmlLabel }

procedure THtmlLabel.AddAttributes(Attributes: THtmlAttributes);
begin
  inherited AddAttributes(Attributes);

  Attributes.AddOptional('for', ForValue);
  Attributes.AddOptional('accesskey', AccessKey);
end;

{ THtmlButton }

procedure THtmlButton.AddAttributes(Attributes: THtmlAttributes);
begin
  inherited AddAttributes(Attributes);

  Attributes.AddOptional('disabled', Disabled);
  Attributes.AddOptional('type', ButtonTypeToText(ButtonType));
  Attributes.AddOptional('value', Value);
end;

function THtmlButton.ButtonTypeToText(ButtonType: THtmlButtonType): TText;
begin
  case ButtonType of
    THtmlButtonType.Button: Result := 'button';
    THtmlButtonType.Reset:  Result := 'reset';
    THtmlButtonType.Submit: Result := 'submit';
    else
      raise EException.Create('Unknown button type');
  end;
end;

end.