| 1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
| ///////////////////////////////////////////////////////////////////////////
// //
// Copyright (c) 2015 by Charta Software B.V. //
// All rights reserved //
// //
// Version: 1.7.0.83525 //
// Web site: https://pascal.chartasoftware.com/ //
// //
// This code and information are provided "as is" without warranty of //
// any kind. Dissemination of this information or reproduction of //
// this material is strictly forbidden unless prior written permission //
// is obtained from Charta Software B.V.. //
// //
///////////////////////////////////////////////////////////////////////////
unit Iterator.Tree;
interface
{$SCOPEDENUMS ON}
uses
Boolean,
Iterator,
Object_.ReferenceCounted;
type
TTreeIteratorState = (Parent, Children, Done);
TTreeVerticalOrder = (TopDown, BottomUp);
TChildIteratorFactory<TElement> = class(TReferenceCountedObject)
public
function CreateChildIterator(Parent: TElement): TIterator<TElement>; virtual; abstract;
end;
TTreeIterator<TElement> = class(TIterator<TElement>)
protected
Parent: TElement;
Order: TTreeVerticalOrder;
State: TTreeIteratorState;
ChildIterator: TIterator<TElement>;
ChildSubtreeIterator: TIterator<TElement>;
ChildIteratorFactory: TChildIteratorFactory<TElement>;
function GetCurrent(): TElement; override;
procedure EnterCurrentChild(EndState: TTreeIteratorState);
public
constructor Create(Parent: TElement; Order: TTreeVerticalOrder; ChildIteratorFactory: TChildIteratorFactory<TElement>); virtual;
destructor Destroy(); override;
function IsValid(): TBoolean; override;
procedure GotoNext(); override;
end;
implementation
uses
Exception.Enumeration,
Iterator.Exception;
{ TTreeIterator<TElement> }
constructor TTreeIterator<TElement>.Create(Parent: TElement; Order: TTreeVerticalOrder; ChildIteratorFactory: TChildIteratorFactory<TElement>);
begin
inherited Create();
Self.Parent := Parent;
Self.Order := Order;
Self.ChildIteratorFactory := ChildIteratorFactory;
Self.ChildIterator := ChildIteratorFactory.CreateChildIterator(Parent);
ChildIteratorFactory.AddReference();
case Order of
TTreeVerticalOrder.TopDown:
State := TTreeIteratorState.Parent;
TTreeVerticalOrder.BottomUp:
begin
State := TTreeIteratorState.Children;
EnterCurrentChild(TTreeIteratorState.Parent);
end
else
raise EUnknownEnumerationValue.Create('Unknown vertical order');
end;
end;
destructor TTreeIterator<TElement>.Destroy();
begin
ChildSubtreeIterator.Free();
ChildIterator.Free();
ChildIteratorFactory.ReleaseReference();
inherited Destroy();
end;
procedure TTreeIterator<TElement>.EnterCurrentChild(EndState: TTreeIteratorState);
begin
ChildSubtreeIterator.Free();
ChildSubtreeIterator := nil;
while (ChildSubtreeIterator = nil) and ChildIterator.IsValid() do
begin
ChildSubtreeIterator := TTreeIterator<TElement>.Create(ChildIterator.Current, Order, ChildIteratorFactory);
if not ChildSubtreeIterator.IsValid() then
begin
ChildSubtreeIterator.Free();
ChildSubtreeIterator := nil;
ChildIterator.GotoNext();
end;
end;
if ChildSubtreeIterator = nil then
State := EndState;
end;
function TTreeIterator<TElement>.GetCurrent(): TElement;
begin
case State of
TTreeIteratorState.Parent:
Result := Parent;
TTreeIteratorState.Children:
Result := ChildSubtreeIterator.Current;
TTreeIteratorState.Done:
raise EIteratorNotValid.Create();
else
raise EUnknownEnumerationValue.Create('Unknown iterator state');
end;
end;
procedure TTreeIterator<TElement>.GotoNext();
begin
if State <> TTreeIteratorState.Done then
begin
case Order of
TTreeVerticalOrder.TopDown:
case State of
TTreeIteratorState.Parent:
begin
State := TTreeIteratorState.Children;
EnterCurrentChild(TTreeIteratorState.Done);
end;
TTreeIteratorState.Children:
begin
ChildSubtreeIterator.GotoNext();
if not ChildSubtreeIterator.IsValid() then
begin
ChildIterator.GotoNext();
EnterCurrentChild(TTreeIteratorState.Done);
end;
end;
else
raise EUnknownEnumerationValue.Create('Unknown iterator state');
end;
TTreeVerticalOrder.BottomUp:
case State of
TTreeIteratorState.Parent:
State := TTreeIteratorState.Done;
TTreeIteratorState.Children:
begin
ChildSubtreeIterator.GotoNext();
if not ChildSubtreeIterator.IsValid() then
begin
ChildIterator.GotoNext();
EnterCurrentChild(TTreeIteratorState.Parent);
end;
end;
else
raise EUnknownEnumerationValue.Create('Unknown iterator state');
end;
else
raise EUnknownEnumerationValue.Create('Unknown vertical order');
end;
end
else
raise EIteratorPassedEnd.Create();
end;
function TTreeIterator<TElement>.IsValid(): TBoolean;
begin
Result := State <> TTreeIteratorState.Done;
end;
end.
|