1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
| ///////////////////////////////////////////////////////////////////////////
// //
// Copyright (c) 2015 by Charta Software B.V. //
// All rights reserved //
// //
// Version: 1.7.0.83525 //
// Web site: https://pascal.chartasoftware.com/ //
// //
// This code and information are provided "as is" without warranty of //
// any kind. Dissemination of this information or reproduction of //
// this material is strictly forbidden unless prior written permission //
// is obtained from Charta Software B.V.. //
// //
///////////////////////////////////////////////////////////////////////////
unit Sql.Database.Logical.Versioned;
interface
uses
Boolean,
Collection.List,
Exception,
Integer,
Sql.Database,
Sql.Database.Logical.Annotating,
Sql.Database.Logical.UpdateOperation,
Sql.Expression,
Sql.Result,
Sql.Statement,
Sql.Statement.DataDefinition.Table.Alter,
Sql.Statement.DataDefinition.Table.Create,
Sql.Statement.DataManipulation,
Sql.Table,
Sql.Table.Column,
Sql.Transaction,
Sql.Transaction.Log,
Text;
type
TSqlVersioningTransaction = class(TObject)
protected
FId: TInteger;
FLog: TSqlTransactionLog;
public
constructor Create(const Id: TInteger; Log: TSqlTransactionLog); virtual;
property Id: TInteger read FId;
property Log: TSqlTransactionLog read FLog;
end;
ESqlVersionedDatabase = class(EException);
ESqlVersioningIncompatibility = class(ESqlVersionedDatabase);
TSqlVersioningUpdateOperation = class(TLogicalSqlUpdateOperation)
private
TransactionId: TInteger;
protected
function IsManagedColumn(Column: TSqlTableColumn): TBoolean; override;
public
constructor Create(Database: TSqlDatabase; const TemporaryIdentifier: TText; Table: TSqlTable; Columns: TList<TSqlTableColumn>; const TransactionId: TInteger); reintroduce; virtual;
function CreatePresentRestriction(): TSqlExpression; override;
procedure AddManagingColumns(InsertSelect: TSqlInsertSelect); override;
procedure ValidateManagedColumns(); override;
end;
TVersionedSqlDatabase = class(TAnnotatingSqlDatabase)
protected
VersioningTransaction: TSqlVersioningTransaction;
Transaction: TSqlTransaction;
procedure StartUpdateOperation(Table: TSqlTable); override;
procedure EndUpdateOperation(); override;
procedure AddDeleteRestrictions(Delete: TSqlDelete; Table: TSqlTable); override;
procedure AddDeleteAssignments(Update: TSqlUpdate; Table: TSqlTable); override;
procedure AddManagingRestrictions(Expression: TSqlExpression); override;
procedure UpdateManagingColumns(UpdateOperation: TLogicalSqlUpdateOperation); override;
function IsManaged(Table: TSqlTable): TBoolean; overload; override;
function IsManaged(Table: TSqlTable; Column: TSqlTableColumn): TBoolean; overload; override;
function CreateUpdateOperation(Table: TSqlTable; Columns: TList<TSqlTableColumn>): TLogicalSqlUpdateOperation; override;
procedure HandleAlterTable(AlterTable: TSqlAlterTable);
procedure HandleCreateTable(CreateTable: TSqlCreateTable);
public
function Query(Statement: TSqlStatement; ResultMethod: TSqlQueryResultMethod = sqrmStoreResult): TSqlResult; override;
function StartTransaction(): TSqlTransaction; override;
procedure EndTransaction(Transaction: TSqlTransaction); override;
end;
implementation
uses
Object_.List,
Sql,
Sql.Comparison,
Sql.Database.Logical.Versioned.RewriteRule,
Sql.Exception,
Sql.Literal,
Sql.Operator_.Binary,
Sql.Operator_.Unary,
Sql.Rewriter,
Sql.Rewriter.Rule,
Sql.Statement.ResultSet,
Sql.Statement.ResultSet.Select,
Sql.Table.Column.Reference,
Sql.Table.Index,
Sql.Table.Index.Column;
{ TSqlVersioningTransaction }
constructor TSqlVersioningTransaction.Create(const Id: TInteger; Log: TSqlTransactionLog);
begin
inherited Create();
FId := Id;
FLog := Log;
end;
{ TVersionedSqlDatabase }
function TVersionedSqlDatabase.StartTransaction(): TSqlTransaction;
begin
Transaction := inherited StartTransaction();
Result := Transaction;
end;
procedure TVersionedSqlDatabase.StartUpdateOperation(Table: TSqlTable);
var
Log: TSqlTransactionLog;
begin
if Transaction <> nil then
begin
Log := Table.Lifetime.Log;
if VersioningTransaction = nil then
begin
// TODO: Currently we store only one VersioningTransaction, however, more than one Log may be in effect
VersioningTransaction := TSqlVersioningTransaction.Create(Log.Log(Database, Transaction), Log);
end
else if VersioningTransaction.Log <> Log then
raise ESqlVersioningIncompatibility.Create('Mixing different transaction logs in one transaction');
end
else
raise ESqlVersionedDatabase.Create('Transaction required');
end;
procedure TVersionedSqlDatabase.UpdateManagingColumns(UpdateOperation: TLogicalSqlUpdateOperation);
begin
Database.Query(
Update(
[ UpdateOperation.Table, UpdateOperation.TemporaryTable ],
[ Assign(UpdateOperation.Table.Lifetime.RemoveTransactionId, Null) ],
[
UpdateOperation.CreateRowEquals(),
UpdateOperation.Table.Lifetime.RemoveTransactionId = VersioningTransaction.Id
]
)
);
end;
procedure TVersionedSqlDatabase.EndTransaction(Transaction: TSqlTransaction);
begin
inherited EndTransaction(Transaction);
Self.Transaction := nil;
VersioningTransaction.Free();
VersioningTransaction := nil;
end;
procedure TVersionedSqlDatabase.AddDeleteAssignments(Update: TSqlUpdate; Table: TSqlTable);
begin
Update.Assignments.Add(Assign(Table.Lifetime.RemoveTransactionId, VersioningTransaction.Id));
end;
procedure TVersionedSqlDatabase.AddDeleteRestrictions(Delete: TSqlDelete; Table: TSqlTable);
begin
Delete.Restrictions.Add(Equal(Table.Lifetime.AddTransactionId, VersioningTransaction.Id));
end;
procedure TVersionedSqlDatabase.AddManagingRestrictions(Expression: TSqlExpression);
var
RewriteRule: TSqlRewriteRule;
Rewriter: TSqlRewriter;
begin
RewriteRule := TVersioningSqlRewriteRule.Create();
Rewriter := TSqlRewriter.Create(RewriteRule);
Rewriter.DecorateExpression(Expression);
Rewriter.Free();
RewriteRule.Free();
end;
procedure TVersionedSqlDatabase.EndUpdateOperation();
begin
end;
procedure TVersionedSqlDatabase.HandleAlterTable(AlterTable: TSqlAlterTable);
var
WorkingCopy: TSqlAlterTable;
Specification: TSqlExpression;
AddKey: TSqlAddKey;
OriginalKey: TSqlTableKey;
ExtendedKey: TSqlTableKey;
TemporaryKeys: TList<TSqlTableKey>;
Column: TSqlTableIndexColumn;
begin
if IsManaged(AlterTable.Table) then
begin
WorkingCopy := AlterTable.CopyAlterTable();
TemporaryKeys := TObjectList<TSqlTableKey>.Create();
for Specification in WorkingCopy.Specifications do
begin
if Specification is TSqlAddKey then
begin
AddKey := Specification as TSqlAddKey;
OriginalKey := AddKey.Key;
if (OriginalKey is TSqlPrimaryKey) or (OriginalKey is TSqlUniqueKey) then
begin
if OriginalKey is TSqlPrimaryKey then
ExtendedKey := TSqlPrimaryKey.Create([])
else
ExtendedKey := TSqlUniqueKey.Create((OriginalKey as TSqlUniqueKey).Name, []);
AddKey.Key := ExtendedKey;
for Column in OriginalKey.Columns do
ExtendedKey.Columns.Add(Column);
ExtendedKey.Columns.Add(AlterTable.Table.Lifetime.AddTransactionId);
TemporaryKeys.Add(ExtendedKey);
end;
end;
end;
Database.Query(WorkingCopy);
TemporaryKeys.Free();
end
else
Database.Query(AlterTable);
end;
procedure TVersionedSqlDatabase.HandleCreateTable(CreateTable: TSqlCreateTable);
var
WorkingCopy: TSqlCreateTable;
Expression: TSqlExpression;
Key: TSqlTableKey;
CreateKey: TSqlCreateKey;
CreatedKey: TSqlTableKey;
CreatedKeys: TList<TSqlTableKey>;
Column: TSqlTableIndexColumn;
begin
if IsManaged(CreateTable.Table) then
begin
CreatedKeys := TObjectList<TSqlTableKey>.Create();
WorkingCopy := CreateTable.CopyCreateTable();
for Expression in WorkingCopy.Specifications do
begin
if Expression is TSqlCreateKey then
begin
CreateKey := Expression as TSqlCreateKey;
Key := CreateKey.Key;
if (Key is TSqlPrimaryKey) or (Key is TSqlUniqueKey) then
begin
if Key is TSqlPrimaryKey then
CreatedKey := TSqlPrimaryKey.Create([])
else
CreatedKey := TSqlUniqueKey.Create((Key as TSqlUniqueKey).Name, []);
CreateKey.Key := CreatedKey;
for Column in Key.Columns do
CreatedKey.Columns.Add(Column);
CreatedKey.Columns.Add(CreateTable.Table.Lifetime.AddTransactionId);
CreatedKeys.Add(CreatedKey);
end;
end;
end;
Database.Query(WorkingCopy);
CreatedKeys.Free();
end
else
Database.Query(CreateTable);
end;
function TVersionedSqlDatabase.Query(Statement: TSqlStatement; ResultMethod: TSqlQueryResultMethod): TSqlResult;
begin
Result := nil;
UseOwnInsertId := False;
Statement.AddReference();
try
if Statement is TSqlInsertValues then
HandleInsertValues(Statement as TSqlInsertValues, TSqlAnnotatingInsertType.Insert)
else if Statement is TSqlInsertSelect then
HandleInsertSelect(Statement as TSqlInsertSelect, TSqlAnnotatingInsertType.Insert)
else if Statement is TSqlReplaceValues then
HandleInsertValues(Statement as TSqlReplaceValues, TSqlAnnotatingInsertType.Replace)
else if Statement is TSqlResultSetStatement then
Result := HandleResultSetStatement(Statement as TSqlResultSetStatement, ResultMethod)
else if Statement is TSqlDelete then
HandleDelete(Statement as TSqlDelete)
else if Statement is TSqlUpdate then
HandleUpdate(Statement as TSqlUpdate)
else if Statement is TSqlCreateTable then
HandleCreateTable(Statement as TSqlCreateTable)
else if Statement is TSqlAlterTable then
HandleAlterTable(Statement as TSqlAlterTable)
else
Result := Database.Query(Statement, ResultMethod);
finally
Statement.ReleaseReference();
end;
end;
function TVersionedSqlDatabase.CreateUpdateOperation(Table: TSqlTable; Columns: TList<TSqlTableColumn>): TLogicalSqlUpdateOperation;
begin
Result := TSqlVersioningUpdateOperation.Create(Database, 'versioning$temporary', Table, Columns, VersioningTransaction.Id);
end;
function TVersionedSqlDatabase.IsManaged(Table: TSqlTable; Column: TSqlTableColumn): TBoolean;
begin
Result := (Column = Table.LifeTime.AddTransactionId.Column) or (Column = Table.LifeTime.RemoveTransactionId.Column);
end;
function TVersionedSqlDatabase.IsManaged(Table: TSqlTable): TBoolean;
begin
Result := Table.Lifetime <> nil;
end;
{ TSqlVersioningUpdateOperation }
procedure TSqlVersioningUpdateOperation.AddManagingColumns(InsertSelect: TSqlInsertSelect);
begin
InsertSelect.Select.Columns.AddExpression(TSqlLiteralInteger.Create(TransactionId));
InsertSelect.Columns.Add(Table.LifeTime.AddTransactionId);
end;
constructor TSqlVersioningUpdateOperation.Create(Database: TSqlDatabase; const TemporaryIdentifier: TText; Table: TSqlTable; Columns: TList<TSqlTableColumn>; const TransactionId: TInteger);
begin
inherited Create(Database, TemporaryIdentifier, Table, Columns);
Self.TransactionId := TransactionId;
end;
function TSqlVersioningUpdateOperation.CreatePresentRestriction(): TSqlExpression;
begin
Result := Table.Lifetime.RemoveTransactionId.IsNull;
end;
function TSqlVersioningUpdateOperation.IsManagedColumn(Column: TSqlTableColumn): TBoolean;
begin
Result := (Column = Table.Lifetime.AddTransactionId.Column) or (Column = Table.Lifetime.RemoveTransactionId.Column);
end;
procedure TSqlVersioningUpdateOperation.ValidateManagedColumns();
var
Select: TSqlSelect;
OrAll: TSqlOrAll;
TemporaryColumn: TSqlTableColumn;
begin
Select := TSqlSelect.Create();
Select.Columns.AddExpression(TSqlLiteralBoolean.Create(True));
Select.From.Add(TemporaryTable.ToExpression());
OrAll := TSqlOrAll.Create();
if ManagedColumns.Contains(Table.Lifetime.AddTransactionId.Column) then
begin
TemporaryColumn := ToTemporary[Table.Lifetime.AddTransactionId.Column];
OrAll.Expressions.Add(
not Sql.OrAll([
TSqlIsNull.Create(TSqlTableColumnReference.Create(TemporaryColumn)),
TSqlEqual.Create(TSqlTableColumnReference.Create(TemporaryColumn), TSqlLiteralInteger.Create(TransactionId))
])
);
end;
if ManagedColumns.Contains(Table.Lifetime.RemoveTransactionId.Column) then
OrAll.Expressions.Add(TSqlNot.Create(TSqlIsNull.Create(TSqlTableColumnReference.Create(ToTemporary[Table.Lifetime.RemoveTransactionId.Column]))));
Select.Restrictions.Add(OrAll);
if Database.Exists(Select) then
raise ESql.Create('Illegal value specified for version column');
end;
end.
|