Sql.Functions.FlowControl

Unit
Source
Symbols

Symbol	Description
TSqlCase
TSqlCaseBranch
TSqlIfNull
TSqlIfThenElse
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
///////////////////////////////////////////////////////////////////////////
//                                                                       //
//  Copyright (c) 2015 by Charta Software B.V.                           //
//  All rights reserved                                                  //
//                                                                       //
//  Version:  1.7.0.83525                                                //
//  Web site: https://pascal.chartasoftware.com/                         //
//                                                                       //
//  This code and information are provided "as is" without warranty of   //
//  any kind. Dissemination of this information or reproduction of       //
//  this material is strictly forbidden unless prior written permission  //
//  is obtained from Charta Software B.V..                               //
//                                                                       //
///////////////////////////////////////////////////////////////////////////

unit Sql.Functions.FlowControl;

interface

uses
  Boolean,
  Collection,
  Collection.List,
  Sql.Expression,
  Sql.Functions,
  Type_;

type
  TSqlIfNull = class(TSqlFunction)
  private
    FCondition: TSqlExpression;
    FValue:     TSqlExpression;

    procedure   SetCondition(const Value: TSqlExpression);
    procedure   SetValue(const Value: TSqlExpression);

  protected
    procedure   AddComposingExpressions(Target: TCollection<TSqlExpression>); override;

  public
    constructor Create(Condition: TSqlExpression; Value: TSqlExpression); reintroduce; virtual;
    destructor  Destroy(); override;

    function    CopyFunction(): TSqlFunction; override;
    function    CopyIfNull(): TSqlIfNull;
    function    GetType(): TType; override;

    function    AggregatesRows(): TBoolean; override;

    property    Condition: TSqlExpression read FCondition write SetCondition;
    property    Value: TSqlExpression read FValue write SetValue;
  end;

  TSqlIfThenElse = class(TSqlFunction)
  private
    FCondition:  TSqlExpression;
    FFalseValue: TSqlExpression;
    FTrueValue:  TSqlExpression;

    procedure   SetCondition(const Value: TSqlExpression);
    procedure   SetFalseValue(const Value: TSqlExpression);
    procedure   SetTrueValue(const Value: TSqlExpression);

  protected
    procedure   AddComposingExpressions(Target: TCollection<TSqlExpression>); override;

  public
    constructor Create(Condition: TSqlExpression; TrueValue: TSqlExpression; FalseValue: TSqlExpression); reintroduce; virtual;
    destructor  Destroy(); override;

    function    CopyFunction(): TSqlFunction; override;
    function    CopyIfThenElse(): TSqlIfThenElse;

    function    GetType(): TType; override;
    function    AggregatesRows(): TBoolean; override;

    property    Condition: TSqlExpression read FCondition write SetCondition;
    property    TrueValue: TSqlExpression read FTrueValue write SetTrueValue;
    property    FalseValue: TSqlExpression read FFalseValue write SetFalseValue;
  end;

  TSqlCaseBranch = class(TObject)
  private
    FCondition: TSqlExpression;
    FValue:     TSqlExpression;

    procedure   SetCondition(const Value: TSqlExpression);
    procedure   SetValue(const Value: TSqlExpression);
    
  public
    constructor Create(Condition: TSqlExpression; Value: TSqlExpression); virtual;
    destructor  Destroy(); override;

    function    Copy(): TSqlCaseBranch;
    function    AggregatesRows(): TBoolean; 
  
    property    Condition: TSqlExpression read FCondition write SetCondition;
    property    Value: TSqlExpression read FValue write SetValue;
  end;

  TSqlCase = class(TSqlFunction)
  private
    FElseValue: TSqlExpression;

    procedure   SetElseValue(const Value: TSqlExpression);
    
  protected
    procedure   AddComposingExpressions(Target: TCollection<TSqlExpression>); override;

  public
    Branches: TList<TSqlCaseBranch>;

    constructor Create(); override;
    destructor  Destroy(); override;

    function    CopyFunction(): TSqlFunction; override;
    function    CopyCase(): TSqlCase;

    function    GetType(): TType; override;
    function    AggregatesRows(): TBoolean; override;

    property    ElseValue: TSqlExpression read FElseValue write SetElseValue;
  end;

implementation

uses
  Integer._32,
  Iterator,
  Object_.List;

{ TSqlIfNull }

procedure TSqlIfNull.AddComposingExpressions(Target: TCollection<TSqlExpression>);
begin
  inherited AddComposingExpressions(Target);

  Target.Add(Condition);
  Target.Add(Value);
end;

function TSqlIfNull.AggregatesRows(): TBoolean;
begin
  Result := Condition.AggregatesRows() or Value.AggregatesRows();
end;

function TSqlIfNull.CopyFunction(): TSqlFunction;
begin
  Result := CopyIfNull();
end;

function TSqlIfNull.CopyIfNull(): TSqlIfNull;
begin
  Result := TSqlIfNull.Create(Condition.Copy(), Value.Copy());
end;

constructor TSqlIfNull.Create(Condition: TSqlExpression; Value: TSqlExpression);
begin
  inherited Create();

  Self.Condition := Condition;
  Self.Value     := Value;
end;

destructor TSqlIfNull.Destroy();
begin
  Condition.ReleaseReference();
  Value.ReleaseReference();

  inherited Destroy();
end;

function TSqlIfNull.GetType(): TType;
begin
  Result := Condition.GetType().CommonType(Value.GetType());
end;

procedure TSqlIfNull.SetCondition(const Value: TSqlExpression);
begin
  if Value <> Condition then
  begin
    Value.AddReference();
    Condition.ReleaseReference();
    
    FCondition := Value;
  end;
end;

procedure TSqlIfNull.SetValue(const Value: TSqlExpression);
begin
  if Value <> Self.Value then
  begin
    Value.AddReference();
    Self.Value.ReleaseReference();
    
    FValue := Value;
  end;
end;

{ TSqlIfThenElse }

procedure TSqlIfThenElse.AddComposingExpressions(Target: TCollection<TSqlExpression>);
begin
  inherited AddComposingExpressions(Target);

  Target.Add(Condition);
  Target.Add(TrueValue);
  Target.Add(FalseValue);
end;

function TSqlIfThenElse.AggregatesRows(): TBoolean;
begin
  Result := Condition.AggregatesRows() or TrueValue.AggregatesRows() or FalseValue.AggregatesRows();
end;

function TSqlIfThenElse.CopyFunction(): TSqlFunction;
begin
  Result := CopyIfThenElse();
end;

function TSqlIfThenElse.CopyIfThenElse(): TSqlIfThenElse;
begin
  Result := TSqlIfThenElse.Create(Condition.Copy(), TrueValue.Copy(), FalseValue.Copy());
end;

constructor TSqlIfThenElse.Create(Condition: TSqlExpression; TrueValue: TSqlExpression; FalseValue: TSqlExpression);
begin
  inherited Create();

  Self.Condition  := Condition;
  Self.TrueValue  := TrueValue;
  Self.FalseValue := FalseValue;
end;

destructor TSqlIfThenElse.Destroy();
begin
  Condition.ReleaseReference();
  TrueValue.ReleaseReference();
  FalseValue.ReleaseReference();

  inherited Destroy();
end;

function TSqlIfThenElse.GetType(): TType;
begin
  Result := TrueValue.GetType().CommonType(FalseValue.GetType());
end;

procedure TSqlIfThenElse.SetCondition(const Value: TSqlExpression);
begin
  if Value <> Condition then
  begin
    Value.AddReference();
    Condition.ReleaseReference();
    
    FCondition := Value;
  end;
end;

procedure TSqlIfThenElse.SetFalseValue(const Value: TSqlExpression);
begin
  if Value <> FalseValue then
  begin
    Value.AddReference();
    FalseValue.ReleaseReference();
    
    FFalseValue := Value;
  end;
end;

procedure TSqlIfThenElse.SetTrueValue(const Value: TSqlExpression);
begin
  if Value <> TrueValue then
  begin
    Value.AddReference();
    TrueValue.ReleaseReference();
    
    FTrueValue := Value;
  end;
end;

{ TSqlCase }

procedure TSqlCase.AddComposingExpressions(Target: TCollection<TSqlExpression>);
var
  Branch: TSqlCaseBranch;
begin
  inherited AddComposingExpressions(Target);

  for Branch in Branches do
  begin
    Target.Add(Branch.Condition);
    Target.Add(Branch.Value);
  end;

  if ElseValue <> nil then
    Target.Add(ElseValue);
end;

function TSqlCase.AggregatesRows(): TBoolean;
var
  Iterator: TIterator<TSqlCaseBranch>;
begin
  Result   := (ElseValue <> nil) and ElseValue.AggregatesRows();
  Iterator := Branches.CreateIterator();

  while not Result and Iterator.IsValid do
  begin
    Result := Iterator.Current.AggregatesRows();
    Iterator.GotoNext();
  end;
  
  Iterator.Free();
end;

function TSqlCase.CopyCase(): TSqlCase;
var
  Branch: TSqlCaseBranch;
begin
  Result := TSqlCase.Create();

  for Branch in Branches do
    Result.Branches.Add(Branch.Copy());

  if ElseValue <> nil then
    Result.ElseValue := ElseValue.Copy();
end;

function TSqlCase.CopyFunction(): TSqlFunction;
begin
  Result := CopyCase();
end;

constructor TSqlCase.Create();
begin
  inherited Create();

  Branches := TObjectList<TSqlCaseBranch>.Create();
end;

destructor TSqlCase.Destroy();
begin
  Branches.Free();
  ElseValue.ReleaseReference();

  inherited Destroy();
end;

function TSqlCase.GetType(): TType;
var
  i: TInteger32;
begin
  Result := Branches[0].Value.GetType();

  for i := 1 to Branches.Count - 1 do
    Result := Result.CommonType(Branches[i].Value.GetType());

  if ElseValue <> nil then
    Result := Result.CommonType(ElseValue.GetType());
end;

procedure TSqlCase.SetElseValue(const Value: TSqlExpression);
begin
  if Value <> ElseValue then
  begin
    Value.AddReference();
    ElseValue.ReleaseReference();

    FElseValue := Value;
  end;
end;

{ TSqlCaseBranch }

function TSqlCaseBranch.AggregatesRows(): TBoolean;
begin
  Result := Condition.AggregatesRows() or Value.AggregatesRows();
end;

function TSqlCaseBranch.Copy(): TSqlCaseBranch;
begin
  Result := TSqlCaseBranch.Create(Condition, Value);
end;

constructor TSqlCaseBranch.Create(Condition: TSqlExpression; Value: TSqlExpression);
begin
  inherited Create();

  Self.Condition := Condition;
  Self.Value     := Value;
end;

destructor TSqlCaseBranch.Destroy();
begin
  Condition.ReleaseReference();
  Value.ReleaseReference();

  inherited Destroy();
end;

procedure TSqlCaseBranch.SetCondition(const Value: TSqlExpression);
begin
  if Value <> Condition then
  begin
    Value.AddReference();
    Condition.ReleaseReference();
    
    FCondition := Value;
  end;
end;

procedure TSqlCaseBranch.SetValue(const Value: TSqlExpression);
begin
  if Value <> Self.Value then
  begin
    Value.AddReference();
    Self.Value.ReleaseReference();

    FValue := Value;
  end;
end;

end.