Sql.Table

Unit
Source
Symbols

Symbol	Description
TSqlBranchSetInterface
TSqlLifetimeInterface
TSqlTable	Abstract base class for tables that can be queried using SQL statements.
TSqlTableExpressionBuilder
TSqlTableInterface
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
///////////////////////////////////////////////////////////////////////////
//                                                                       //
//  Copyright (c) 2015 by Charta Software B.V.                           //
//  All rights reserved                                                  //
//                                                                       //
//  Version:  1.7.0.83525                                                //
//  Web site: https://pascal.chartasoftware.com/                         //
//                                                                       //
//  This code and information are provided "as is" without warranty of   //
//  any kind. Dissemination of this information or reproduction of       //
//  this material is strictly forbidden unless prior written permission  //
//  is obtained from Charta Software B.V..                               //
//                                                                       //
///////////////////////////////////////////////////////////////////////////

unit Sql.Table;

interface

uses
  Boolean,
  Code.AggregateFunction,
  Collection.List,
  Collection.Set_,
  DataMethod,
  Integer,
  Object_.Base,
  Sql.Builder,
  Sql.Database,
  Sql.Database.Logical.Branching.BranchSet.Handler,
  Sql.Expression,
  Sql.Expression.Row,
  Sql.ObjectFactory,
  Sql.Operator_.Assign,
  Sql.Scope,
  Sql.Statement.ResultSet,
  Sql.Table.Column,
  Sql.Table.Column.Order,
  Sql.Table.Expression,
  Sql.Table.Index,
  Sql.Table.Index.Column,
  Sql.Transaction.Log,
  StructuredDocument.Node,
  Text,
  Type_,
  Type_.Structured;

type
  TSqlTable              = class;
  TSqlLifetimeInterface  = class;
  TSqlBranchSetInterface = class;

  TSqlTableExpressionBuilder = record
  public
    Expression: TSqlTableExpression;

    class operator Implicit(Table: TSqlTable): TSqlTableExpressionBuilder;
    class operator Implicit(Expression: TSqlTableExpression): TSqlTableExpressionBuilder;
    class operator Implicit(Expression: TSqlTableExpressionBuilder): TSqlTableExpression;
  end;

  TSqlTable = class(TBaseObject)
  private
    FScope:         TSqlScope;
    FCaption:       TDocumentNode;
    FAliasName:     TText;
    FObjectFactory: TSqlObjectFactory;

    procedure   SetAliasName(const Value: TText);
    procedure   SetObjectFactory(const Value: TSqlObjectFactory);

  protected
    var
      FColumns:              TList<TSqlTableColumn>;
      FDefaultHiddenColumns: TSet<TSqlTableColumn>;
      FPrimaryKey:           TSqlPrimaryKey;
      FUniqueKeys:           TList<TSqlUniqueKey>;
      FForeignKeys:          TList<TSqlForeignKey>;
      FIndexes:              TList<TSqlIndex>;
      FOrder:                TSqlTableColumnOrder;

    var
      TableScope: TSqlScope;

    function    GetIdentifier(): TText; virtual;
    procedure   SetCaption(const Value: TDocumentNode);
    procedure   SetScope(const Value: TSqlScope);

  protected
    function    SuppressPrimaryKeyException(): TBoolean; virtual; deprecated;
    function    ShouldCheckPrimaryKey(): TBoolean; virtual;

    procedure   CheckPrimaryKey();

  public
    TableIdentifier:      TText;
    Lifetime:             TSqlLifetimeInterface;
    BranchSet:            TSqlBranchSetInterface;
    UnversionedTable:     TSqlTable;
    SupportsTransactions: TBoolean deprecated; // TODO: All tables should support transactions
    IsTemporary:          TBoolean;
    IsRecord:             TBoolean;

    constructor Create(const Identifier: TText); reintroduce; virtual;
    destructor  Destroy(); override;

    procedure   AfterConstruction(); override;

    function    ToText(): TText; override;

    function    GetType(): TType; virtual;
    function    CreateKeyType(): TRecordType;

    function    ToExpression(): TSqlTableExpression; virtual; abstract;
    function    ShouldAutoRefresh(): TBoolean; virtual;

    function    Current(): TSqlTableExpression;
    function    At(const RevisionId: TInteger): TSqlTableExpression;
    function    History(): TSqlTableExpression;
    function    ForMethod(Method: TDataMethod): TSqlTableExpression;

    function    CreateColumn(const Identifier: TText; Type_: TType): TSqlTableColumn; overload;
    function    CreateColumn(const Identifier: TText; Caption: TDocumentNode; Type_: TType): TSqlTableColumn; overload;
    function    CreateColumn(SourceColumn: TSqlTableColumn): TSqlTableColumn; overload;
    function    CreateColumn(SourceColumn: TSqlResultSetColumn): TSqlTableColumn; overload;

    function    IsMethodAllowedExpression(Method: TDataMethod): TSqlExpression;

    procedure   Insert(Database: TSqlDatabase; Columns: TList<TSqlTableColumn>; Rows: TList<TSqlRow>); virtual; deprecated 'Please use a foreign key or a trigger';
    procedure   Update(Database: TSqlDatabase; Assignments: TList<TSqlAssign>; Restrictions: TList<TSqlExpression>); virtual; deprecated 'Please use a foreign key or a trigger';
    procedure   Delete(Database: TSqlDatabase; Restrictions: TList<TSqlExpression>); virtual; deprecated 'Please use a foreign key or a trigger';

    function    SetPrimaryKey(Columns: array of TSqlTableIndexColumn): TSqlPrimaryKey; virtual;
    function    AddUniqueKey(Name: TText; Columns: array of TSqlTableIndexColumn): TSqlUniqueKey; virtual;
    function    AddNonUniqueIndex(Name: TText; Columns: array of TSqlTableIndexColumn): TSqlNonUniqueIndex; virtual;
    function    AddSpatialIndex(Name: TText; Columns: array of TSqlTableIndexColumn): TSqlSpatialIndex;
    function    AddForeignKey(Name: TText; Columns: array of TSqlTableIndexColumn; ReferenceTable: TSqlTable; const ReferenceColumns: array of TSqlTableColumn; Type_: TSqlForeignKeyType): TSqlForeignKey;

    function    GetNonBranchingColumns(): TList<TSqlTableColumn>;

    procedure   AddVersioning(Log: TSqlTransactionLog);
    procedure   AddBranching(Handler: TBranchSetHandler);
    function    IsBranching(): TBoolean; virtual;

    procedure   AddAggregate(Function_: TAggregateFunction; const Columns: array of TSqlTableColumn);

    property    Scope: TSqlScope read FScope write SetScope;
    property    Identifier: TText read GetIdentifier;
    property    AliasName: TText read FAliasName write SetAliasName;
    property    Caption: TDocumentNode read FCaption write SetCaption;
    property    Columns: TList<TSqlTableColumn> read FColumns;

    property    PrimaryKey: TSqlPrimaryKey read FPrimaryKey;
    property    Indexes: TList<TSqlIndex> read FIndexes;
    property    UniqueKeys: TList<TSqlUniqueKey> read FUniqueKeys;
    property    ForeignKeys: TList<TSqlForeignKey> read FForeignKeys;

    property    Order: TSqlTableColumnOrder read FOrder;
    property    DefaultHiddenColumns: TSet<TSqlTableColumn> read FDefaultHiddenColumns;
    property    ObjectFactory: TSqlObjectFactory read FObjectFactory write SetObjectFactory;

  public
    class var
      GloballySuppressPrimaryKeyException: TBoolean deprecated;
  end;

  TSqlTableInterface = class(TSqlTable)
  protected
    Table: TSqlTable;

    function    GetIdentifier(): TText; override;

  public
    constructor Create(Table: TSqlTable); reintroduce; virtual;

    function    ToExpression(): TSqlTableExpression; override;

    procedure   Update(Database: TSqlDatabase; Assignments: TList<TSqlAssign>; Restrictions: TList<TSqlExpression>); override;
    procedure   Delete(Database: TSqlDatabase; Restrictions: TList<TSqlExpression>); override;
  end;

  TSqlLifetimeInterface = class(TSqlTableInterface)
  private
    FLog: TSqlTransactionLog;

  public
    AddTransactionId:    TSqlTableColumnBuilder;
    RemoveTransactionId: TSqlTableColumnBuilder;

    constructor Create(Table: TSqlTable; Log: TSqlTransactionLog); reintroduce; virtual;

    property    Log: TSqlTransactionLog read FLog;
  end;

  TSqlBranchSetInterface = class(TSqlTableInterface)
  private
    FHandler: TBranchSetHandler;

  public
    BranchSetId: TSqlTableColumnBuilder;

    constructor Create(Table: TSqlTable; Handler: TBranchSetHandler); reintroduce; virtual;

    property    Handler: TBranchSetHandler read FHandler;
  end;

implementation

uses
  Exception,
  Exception.NotImplemented,
  Integer.Type_,
  Language.TranslationMap.Registration,
  Language.Translator,
  Object_.List,
  Object_.Reference.Counter,
  Object_.Set_,
  Sql,
  Sql.Language.TranslationMap,
  Sql.Literal,
  Sql.Statement.ResultSet.Select,
  Sql.Table.Column.Reference,
  Sql.Table.Expression.Authorizing,
  Sql.Table.Expression.Reference,
  Sql.Table.Expression.Reference.Temporal,
  Sql.Table.Scope,
  StructuredDocument.Compiler.Text;

{ TSqlTable }

procedure TSqlTable.CheckPrimaryKey();
begin
  if ShouldCheckPrimaryKey() and not SuppressPrimaryKeyException() then
    if PrimaryKey = nil then
      raise EException.Create('Table should have a primary key: ' + ClassName + ', ' + Identifier);
end;

constructor TSqlTable.Create(const Identifier: TText);
begin
  inherited Create();

  Self.TableIdentifier := Identifier;

  SupportsTransactions := True;

  FUniqueKeys  := TObjectList<TSqlUniqueKey>.Create();
  FForeignKeys := TObjectList<TSqlForeignKey>.Create();
  FIndexes     := TObjectList<TSqlIndex>.Create();
  FOrder       := TSqlTableColumnOrder.Create();

  FColumns := TObjectList<TSqlTableColumn>.Create();
  FColumns.ElementManager := TReferenceCounter<TSqlTableColumn>.Create();

  FDefaultHiddenColumns := TObjectSet<TSqlTableColumn>.Create();
  FDefaultHiddenColumns.ElementManager := TReferenceCounter<TSqlTableColumn>.Create();

  TableScope := TSqlTableScope.Create(TableIdentifier, Self);
  TableScope.AddReference();
end;

function TSqlTable.CreateColumn(const Identifier: TText; Type_: TType): TSqlTableColumn;
begin
  Result := CreateColumn(Identifier, TTranslationMapRegistration.ResolveForIdentifier(Identifier), Type_);
end;

procedure TSqlTable.AddAggregate(Function_: TAggregateFunction; const Columns: array of TSqlTableColumn);
var
  Column: TSqlTableColumn;
begin
  for Column in Columns do
    Column.Aggregates.Add(Function_);
end;

procedure TSqlTable.AddBranching(Handler: TBranchSetHandler);
begin
  BranchSet := TSqlBranchSetInterface.Create(Self, Handler);
  BranchSet.BranchSetId := CreateColumn('BranchSetId', tmBranchSetId, TBoundedIntegerType._32);

  DefaultHiddenColumns.Add(BranchSet.BranchSetId);
end;

function TSqlTable.AddForeignKey(Name: TText; Columns: array of TSqlTableIndexColumn; ReferenceTable: TSqlTable; const ReferenceColumns: array of TSqlTableColumn; Type_: TSqlForeignKeyType): TSqlForeignKey;
begin
  Result := TSqlForeignKey.Create(Name, Columns, ReferenceTable.Identifier, ReferenceColumns, Type_);
  ForeignKeys.Add(Result);
end;

function TSqlTable.AddNonUniqueIndex(Name: TText; Columns: array of TSqlTableIndexColumn): TSqlNonUniqueIndex;
begin
  Result := TSqlNonUniqueIndex.Create(Name, Columns);
  Indexes.Add(Result);
end;

procedure TSqlTable.SetAliasName(const Value: TText);
begin
  if Value <> AliasName then
  begin
    FAliasName := Value;
    TableScope.Identifier := Identifier;
  end;
end;

procedure TSqlTable.SetCaption(const Value: TDocumentNode);
begin
  if Value <> Caption then
  begin
    Value.AddReference();
    Caption.ReleaseReference();

    FCaption := Value;
  end;
end;

procedure TSqlTable.SetObjectFactory(const Value: TSqlObjectFactory);
begin
  if Value <> ObjectFactory then
  begin
    FObjectFactory.Free();
    FObjectFactory := Value;
  end;
end;

function TSqlTable.SetPrimaryKey(Columns: array of TSqlTableIndexColumn): TSqlPrimaryKey;
begin
  if PrimaryKey <> nil then
    raise EException.Create('You cannot change the primary key of a table (yet)');

  FPrimaryKey := TSqlPrimaryKey.Create(Columns);
  Result      := PrimaryKey;
end;

procedure TSqlTable.SetScope(const Value: TSqlScope);
begin
  if Value <> Scope then
  begin
    Value.AddReference();
    Scope.ReleaseReference();

    FScope := Value;
  end;

  TableScope.ParentScope := Scope;
end;

function TSqlTable.ShouldAutoRefresh(): TBoolean;
begin
  Result := False;
end;

function TSqlTable.ShouldCheckPrimaryKey(): TBoolean;
begin
  Result := False;
end;

function TSqlTable.SuppressPrimaryKeyException(): TBoolean;
begin
  Result := TSqlTable.GloballySuppressPrimaryKeyException;
end;

function TSqlTable.AddSpatialIndex(Name: TText; Columns: array of TSqlTableIndexColumn): TSqlSpatialIndex;
begin
  Result := TSqlSpatialIndex.Create(Name, Columns);
  Indexes.Add(Result);
end;

function TSqlTable.AddUniqueKey(Name: TText; Columns: array of TSqlTableIndexColumn): TSqlUniqueKey;
begin
  Result := TSqlUniqueKey.Create(Name, Columns);
  UniqueKeys.Add(Result);
end;

procedure TSqlTable.AfterConstruction();
begin
  inherited AfterConstruction();

  CheckPrimaryKey();
end;

function TSqlTable.At(const RevisionId: TInteger): TSqlTableExpression;
var
  Reference: TSqlTemporalTableReference;
begin
  Reference := TSqlTemporalTableReference.Create(Self);
  Reference.RevisionId := RevisionId;

  Result := Reference;
end;

function TSqlTable.CreateKeyType(): TRecordType;
var
  KeyColumn: TSqlTableIndexColumn;
begin
  Result := TRecordType.Create();

  for KeyColumn in PrimaryKey.Columns do
    Result.Members.Add(KeyColumn.Column.CreateMember());
end;

procedure TSqlTable.AddVersioning(Log: TSqlTransactionLog);
var
  LogType: TType;
begin
  LogType := Log.GetType();

  Lifetime := TSqlLifetimeInterface.Create(Self, Log);
  Lifetime.AddTransactionId    := CreateColumn('AddTransactionID', tmAddTransactionID, LogType);
  Lifetime.RemoveTransactionId := CreateColumn('RemoveTransactionID', tmRemoveTransactionID, LogType.Optional);

  DefaultHiddenColumns.Add(LifeTime.AddTransactionId);
  DefaultHiddenColumns.Add(LifeTime.RemoveTransactionId);
end;

function TSqlTable.Current(): TSqlTableExpression;
begin
  Result := TSqlTableReference.Create(Self);
end;

function TSqlTable.CreateColumn(SourceColumn: TSqlTableColumn): TSqlTableColumn;
begin
  Result := TSqlTableColumn.Create();
  Result.Scope        := TableScope;
  Result.Identifier   := SourceColumn.Identifier;
  Result.Caption      := SourceColumn.Caption;
  Result.Type_        := SourceColumn.Type_;
  Result.DefaultValue := SourceColumn.DefaultValue;
  Result.Aggregates.AddAll(SourceColumn.Aggregates);

  Columns.Add(Result);
end;

function TSqlTable.CreateColumn(const Identifier: TText; Caption: TDocumentNode; Type_: TType): TSqlTableColumn;
begin
  Result := TSqlTableColumn.Create();
  Result.Scope        := TableScope;
  Result.Identifier   := Identifier;
  Result.Caption      := Caption;
  Result.Type_        := Type_;
  Result.DefaultValue := nil;

  Columns.Add(Result);
end;

procedure TSqlTable.Delete(Database: TSqlDatabase; Restrictions: TList<TSqlExpression>);
begin
  raise ENotSupported.Create(ClassType, 'Delete');
end;

destructor TSqlTable.Destroy();
begin
  Columns.Free();
  DefaultHiddenColumns.Free();
  Order.Free();
  UniqueKeys.Free();
  ForeignKeys.Free();
  Indexes.Free();
  PrimaryKey.Free();
  Lifetime.Free();
  BranchSet.Free();
  ObjectFactory.Free();

  TableScope.ReleaseReference();
  Scope.ReleaseReference();
  Caption.ReleaseReference();

  inherited Destroy();
end;

function TSqlTable.ForMethod(Method: TDataMethod): TSqlTableExpression;
begin
  Result := TSqlForMethodTableExpression.Create(ToExpression(), Method);
end;

function TSqlTable.GetIdentifier(): TText;
begin
  if AliasName = '' then
    Result := TableIdentifier
  else
    Result := AliasName;
end;

function TSqlTable.GetNonBranchingColumns(): TList<TSqlTableColumn>;
var
  Column: TSqlTableColumn;
begin
  Result := TObjectList<TSqlTableColumn>.Create();
  Result.ElementManager := TReferenceCounter<TSqlTableColumn>.Create();

  for Column in Columns do
  begin
    if not Self.IsBranching() or (Column.Identifier <> BranchSet.BranchSetId.GetIdentifier()) then
      Result.Add(Column);
  end;
end;

function TSqlTable.GetType(): TType;
begin
  Result := nil;
end;

function TSqlTable.History(): TSqlTableExpression;
begin
  Result := TSqlHistoricalTemporalTableReference.Create(Self);
end;

procedure TSqlTable.Insert(Database: TSqlDatabase; Columns: TList<TSqlTableColumn>; Rows: TList<TSqlRow>);
begin
  raise ENotSupported.Create(ClassType, 'Insert');
end;

function TSqlTable.IsBranching(): TBoolean;
begin
  Result := False;
end;

function TSqlTable.IsMethodAllowedExpression(Method: TDataMethod): TSqlExpression;
var
  Row:         TSqlRow;
  Select:      TSqlSelect;
  IndexColumn: TSqlTableIndexColumn;
begin
  Select := TSqlSelect.Create();
  Select.From.Add(ForMethod(Method));

  if PrimaryKey.Columns.Count > 0 then
  begin
    Row := TSqlRow.Create();

    for IndexColumn in PrimaryKey.Columns do
    begin
      Row.Columns.Add(TSqlTableColumnReference.Create(IndexColumn.Column));
      Select.Columns.AddTableColumn(IndexColumn.Column);
    end;

    // TODO: Is IfNull() necessary? Currently subquery views with NULL in their primary key seem to return NULL for ROW IN SELECT (...).
    Result := IfNull(InSubquery(Row, Select), False);
  end
  else
  begin
    Select.Columns.AddExpression(TSqlLiteralInteger.Create(1));
    Result := Exists(Select);
  end;
end;

function TSqlTable.ToText(): TText;
begin
  if Caption <> nil then
    Result := TDocumentToTextCompiler.RenderToText(TTranslator.Default, Caption)
  else
    Result := Identifier;
end;

procedure TSqlTable.Update(Database: TSqlDatabase; Assignments: TList<TSqlAssign>; Restrictions: TList<TSqlExpression>);
begin
  raise ENotSupported.Create(ClassType, 'Update');
end;

function TSqlTable.CreateColumn(SourceColumn: TSqlResultSetColumn): TSqlTableColumn;
begin
  Result := TSqlTableColumn.Create();
  Result.Scope              := TableScope;
  Result.Identifier         := SourceColumn.GetIdentifier();
  Result.Caption            := SourceColumn.GetCaption();
  Result.Type_              := SourceColumn.Expression.GetType();
  Result.ColumnValueFactory := SourceColumn.GetColumnValueFactory();
  Result.DefaultValue       := nil;

  Columns.Add(Result);
end;

{ TSqlTableInterface }

constructor TSqlTableInterface.Create(Table: TSqlTable);
begin
  inherited Create(Table.Identifier);

  Self.Table := Table;
end;

procedure TSqlTableInterface.Delete(Database: TSqlDatabase; Restrictions: TList<TSqlExpression>);
begin
  Table.Delete(Database, Restrictions);
end;

function TSqlTableInterface.ToExpression(): TSqlTableExpression;
begin
  Result := Table.ToExpression();
end;

function TSqlTableInterface.GetIdentifier(): TText;
begin
  Result := Table.Identifier;
end;

procedure TSqlTableInterface.Update(Database: TSqlDatabase; Assignments: TList<TSqlAssign>; Restrictions: TList<TSqlExpression>);
begin
  Table.Update(Database, Assignments, Restrictions);
end;

{ TSqlLifetimeInterface }

constructor TSqlLifetimeInterface.Create(Table: TSqlTable; Log: TSqlTransactionLog);
begin
  inherited Create(Table);

  FLog := Log;
end;

{ TSqlTableExpressionBuilder }

class operator TSqlTableExpressionBuilder.Implicit(Table: TSqlTable): TSqlTableExpressionBuilder;
begin
  Result := Table.ToExpression;
end;

class operator TSqlTableExpressionBuilder.Implicit(Expression: TSqlTableExpression): TSqlTableExpressionBuilder;
begin
  Result.Expression := Expression;
end;

class operator TSqlTableExpressionBuilder.Implicit(Expression: TSqlTableExpressionBuilder): TSqlTableExpression;
begin
  Result := Expression.Expression;
end;

{ TSqlBranchSetInterface }

constructor TSqlBranchSetInterface.Create(Table: TSqlTable; Handler: TBranchSetHandler);
begin
  inherited Create(Table);

  FHandler := Handler;
end;

initialization
  TSqlTable.GloballySuppressPrimaryKeyException := True;

end.