1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
| ///////////////////////////////////////////////////////////////////////////
// //
// Copyright (c) 2015 by Charta Software B.V. //
// All rights reserved //
// //
// Version: 1.7.0.83525 //
// Web site: https://pascal.chartasoftware.com/ //
// //
// This code and information are provided "as is" without warranty of //
// any kind. Dissemination of this information or reproduction of //
// this material is strictly forbidden unless prior written permission //
// is obtained from Charta Software B.V.. //
// //
///////////////////////////////////////////////////////////////////////////
unit Table.Row.Ordering.Column;
interface
{$SCOPEDENUMS ON}
uses
Boolean,
Collection.List,
Dom.Element,
Integer._32,
Text;
type
TSortOrder = (Ascending, Descending);
TSortColumn = class(TObject)
public
Column: TInteger32;
SortOrder: TSortOrder;
function Copy(): TSortColumn;
end;
TSortColumns = class(TObject)
protected
FSortColumns: TList<TSortColumn>;
function GetColumns(Index: TInteger32): TSortColumn;
function IndexOfColumn(ColumnIndex: TInteger32): TInteger32;
function NegateSortOrder(SortOrder: TSortOrder): TSortOrder;
function SortOrderToText(const Value: TSortOrder): TText;
function TextToSortOrder(const Value: TText): TSortOrder;
function CreateDomElementFromColumn(Column: TSortColumn): TDomElement;
function CreateColumnFromDomElement(Element: TDomElement): TSortColumn;
public
constructor Create(); virtual;
destructor Destroy(); override;
procedure SetSort(Index: TInteger32; SortOrder: TSortOrder);
procedure ToggleSort(Index: TInteger32);
procedure Clear();
function Count(): TInteger32;
function IndexOf(Column: TInteger32): TInteger32;
function IsFirstInSortOrder(Column: TInteger32): TBoolean;
procedure AssignFrom(Source: TSortColumns);
function Copy(): TSortColumns;
procedure ReadFromXml(Element: TDomElement);
procedure WriteToXml(Element: TDomElement);
property Columns[Index: TInteger32]: TSortColumn read GetColumns; default;
end;
implementation
uses
Exception.Enumeration,
Iterator,
Object_.List;
{ TSortColumns }
procedure TSortColumns.SetSort(Index: TInteger32; SortOrder: TSortOrder);
var
ColumnIndex: TInteger32;
SortColumn: TSortColumn;
begin
ColumnIndex := IndexOfColumn(Index);
if ColumnIndex = 0 then
Columns[0].SortOrder := SortOrder
else if ColumnIndex > 0 then
begin
SortColumn := Columns[ColumnIndex];
SortColumn.SortOrder := SortOrder;
FSortColumns.ExtractAt(ColumnIndex);
FSortColumns.AddAt(0, SortColumn);
end
else
begin
SortColumn := TSortColumn.Create();
SortColumn.Column := Index;
SortColumn.SortOrder := SortOrder;
FSortColumns.AddAt(0, SortColumn);
end;
end;
function TSortColumns.SortOrderToText(const Value: TSortOrder): TText;
begin
case Value of
TSortOrder.Ascending:
Result := 'ascending';
TSortOrder.Descending:
Result := 'descending';
else
raise EUnknownEnumerationValue.Create('Unknown order');
end;
end;
function TSortColumns.TextToSortOrder(const Value: TText): TSortOrder;
begin
if Value = 'ascending' then
Result := TSortOrder.Ascending
else if Value = 'descending' then
Result := TSortOrder.Descending
else
raise EUnknownEnumerationValue.Create('Unknown sort order: ' + Value);
end;
procedure TSortColumns.ToggleSort(Index: TInteger32);
var
ColumnIndex: TInteger32;
SortColumn: TSortColumn;
begin
ColumnIndex := IndexOfColumn(Index);
if ColumnIndex = 0 then
Columns[0].SortOrder := NegateSortOrder(Columns[0].SortOrder)
else if ColumnIndex > 0 then
begin
SortColumn := Columns[ColumnIndex];
FSortColumns.ExtractAt(ColumnIndex);
FSortColumns.AddAt(0, SortColumn);
end
else
begin
SortColumn := TSortColumn.Create();
SortColumn.Column := Index;
SortColumn.SortOrder := TSortOrder.Ascending;
FSortColumns.AddAt(0, SortColumn);
end;
end;
procedure TSortColumns.WriteToXml(Element: TDomElement);
var
i: TInteger32;
begin
for i := 0 to Count - 1 do
Element.Nodes.Add(CreateDomElementFromColumn(Columns[i]));
end;
procedure TSortColumns.AssignFrom(Source: TSortColumns);
var
i: TInteger32;
begin
FSortColumns.Clear();
for i := 0 to Source.Count - 1 do
FSortColumns.Add(Source[i].Copy());
end;
procedure TSortColumns.Clear();
begin
FSortColumns.Clear();
end;
function TSortColumns.Copy(): TSortColumns;
begin
Result := TSortColumns.Create();
Result.AssignFrom(Self);
end;
function TSortColumns.Count(): TInteger32;
begin
Result := FSortColumns.Count;
end;
constructor TSortColumns.Create();
begin
inherited Create();
FSortColumns := TObjectList<TSortColumn>.Create();
end;
function TSortColumns.CreateDomElementFromColumn(Column: TSortColumn): TDomElement;
begin
Result := TDomElement.Create('Column');
Result.Attributes.Add('Index', Column.Column);
Result.Attributes.Add('Order', SortOrderToText(Column.SortOrder));
end;
function TSortColumns.CreateColumnFromDomElement(Element: TDomElement): TSortColumn;
begin
Result := TSortColumn.Create();
Result.Column := Element.Attributes.Get('Index').AsInteger();
Result.SortOrder := TextToSortOrder(Element.Attributes.Get('Order').AsText());
end;
destructor TSortColumns.Destroy();
begin
FSortColumns.Free();
inherited Destroy();
end;
function TSortColumns.GetColumns(Index: TInteger32): TSortColumn;
begin
Result := FSortColumns[Index];
end;
function TSortColumns.IndexOf(Column: TInteger32): TInteger32;
var
Index: TInteger32;
begin
Result := -1;
Index := 0;
while (Result = -1) and (Index < Count) do
if Columns[Index].Column = Column then
Result := Index
else
Inc(Index);
end;
function TSortColumns.IndexOfColumn(ColumnIndex: TInteger32): TInteger32;
var
Index: TInteger32;
SortColumn: TSortColumn;
begin
Result := -1;
Index := 0;
while (Result = -1) and (Index < Count) do
begin
SortColumn := Columns[Index];
if SortColumn.Column = ColumnIndex then
Result := Index
else
Inc(Index);
end;
end;
function TSortColumns.IsFirstInSortOrder(Column: TInteger32): TBoolean;
begin
Result := (Count > 0) and (Self[0].Column = Column);
end;
function TSortColumns.NegateSortOrder(SortOrder: TSortOrder): TSortOrder;
begin
case SortOrder of
TSortOrder.Ascending:
Result := TSortOrder.Descending;
TSortOrder.Descending:
Result := TSortOrder.Ascending;
else
raise EUnknownEnumerationValue.Create('Unknown sort order');
end;
end;
procedure TSortColumns.ReadFromXml(Element: TDomElement);
var
Iterator: TIterator<TDomElement>;
begin
FSortColumns.Clear();
Iterator := Element.CreateElementWithNameIterator('Column');
while Iterator.IsValid() do
begin
FSortColumns.Add(CreateColumnFromDomElement(Iterator.Current));
Iterator.GotoNext();
end;
Iterator.Free();
end;
{ TSortColumn }
function TSortColumn.Copy(): TSortColumn;
begin
Result := TSortColumn.Create();
Result.Column := Column;
Result.SortOrder := SortOrder;
end;
end.
|