Task.Scheduler.Thread

Unit
Source
Symbols

Symbol	Description
TTaskSchedulerThread	The background thread used by `TTaskScheduler` which handles the actual scheduling and execution of tasks
TTaskThreadPool
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
///////////////////////////////////////////////////////////////////////////
//                                                                       //
//  Copyright (c) 2015 by Charta Software B.V.                           //
//  All rights reserved                                                  //
//                                                                       //
//  Version:  1.7.0.83525                                                //
//  Web site: https://pascal.chartasoftware.com/                         //
//                                                                       //
//  This code and information are provided "as is" without warranty of   //
//  any kind. Dissemination of this information or reproduction of       //
//  this material is strictly forbidden unless prior written permission  //
//  is obtained from Charta Software B.V..                               //
//                                                                       //
///////////////////////////////////////////////////////////////////////////

unit Task.Scheduler.Thread;

interface

uses
  Boolean,
  Collection,
  Collection.List,
  Condition.Projecting,
  Event,
  Integer._32,
  Integer._32.Interval,
  Task,
  Task.Execution.Thread.Pool,
  Task.Execution.Thread.Recurring,
  Task.Group,
  Task.Node.Event,
  Task.Scheduled,
  Task.Scheduled.Event,
  Task.Status,
  Thread,
  Thread.Event,
  Thread.Lock,
  Thread.Synchronization.WaitableQueue,
  Thread.Timer;

type
  TTaskThreadPool = class(TObject)
  public
    TaskClass: TTaskClass;
    Pool:      TTaskExecutionThreadPool;

    constructor Create(TaskClass: TTaskClass; const ConcurrencyRange: TInteger32Interval; MaximumQueueSize: TInteger32); virtual;
    destructor  Destroy(); override;

  public
    type 
      TWithClass = class(TProjectingCondition<TTaskThreadPool, TTaskClass>)
      public
        function    Matches(const Pool: TTaskThreadPool): TBoolean; override;
      end;
  end;

  TTaskSchedulerThread = class(TThread)
  private
    FStatuses: TList<TTaskStatus>;

    procedure   SetStatuses(const Value: TList<TTaskStatus>);

  protected
    AddLock:                TThreadLock;
    Tasks:                  TList<TScheduledTask>;
    TaskGroups:             TList<TScheduledTaskGroup>;
    RecurringTaskExecutors: TCollection<TRecurringTaskExecutionThread>;
    TerminationEvent:       TThreadEvent;
    Timer:                  TThreadTimer;

    procedure   HandleScheduledStop();
    procedure   HandleUpdateStatuses();

    procedure   HandleTaskScheduled(TaskScheduled: TTaskScheduledEvent);
    procedure   HandleTaskStarted(TaskStarted: TTaskStartedEvent);
    procedure   HandleTaskFinished(TaskFinished: TTaskFinishedEvent);

    procedure   HandleTaskGroupScheduled(TaskGroupScheduled: TTaskGroupScheduledEvent);

    procedure   HandleRecurringTaskStarted(TaskStarted: TRecurringTaskStartedEvent);
    procedure   HandleRecurringTaskScheduled(TaskScheduled: TRecurringTaskScheduledEvent);

    procedure   UnscheduleTask(Task: TTask);
    procedure   UnscheduleTaskGroup(Group: TTaskGroup);

    procedure   HandleUnschedule(UnscheduleEvent: TTaskNodeUnscheduledEvent);

    procedure   HandleEvent(Event: TEvent);
    procedure   HandleEvents();

    procedure   UpdateDependencies(Task: TTask);
    procedure   UpdateTaskGroups();
    procedure   QueueIfPossible(ScheduledTask: TScheduledTask);
    function    GetPoolForTask(Task: TTask): TTaskExecutionThreadPool;

    procedure   Execute(); override;

  public
    EventQueue: TWaitableQueue<TEvent>;
    StatusLock: TThreadLock;
    TaskPools:  TList<TTaskThreadPool>;

    constructor Create(); override;
    destructor  Destroy(); override;

    procedure   Terminate(); override;

    property    Statuses: TList<TTaskStatus> read FStatuses write SetStatuses;
  end;

implementation

uses
  Collection.Map,
  DateTime.Calendar.Gregorian,
  DateTime.Calendar.Gregorian.Duration,
  DateTime.Calendar.Gregorian.Instant,
  Mathematics.Sign,
  Object_.List,
  Object_.Map.Hash,
  Object_.Reference.Counter,
  Progress,
  Reference.User,
  Task.Controllable,
  Thread.WaitableObject,
  Thread.WaitableObject.Group;

{ TTaskSchedulerThread }

constructor TTaskSchedulerThread.Create();
begin
  inherited Create();

  AddLock                := TThreadLock.Create();
  StatusLock             := TThreadLock.Create();
  TerminationEvent       := TThreadEvent.Create(True, False);
  RecurringTaskExecutors := TObjectList<TRecurringTaskExecutionThread>.Create();
  Statuses               := TObjectList<TTaskStatus>.Create();
  Timer                  := TThreadTimer.Create(False);
  EventQueue             := TWaitableQueue<TEvent>.Create(MAXIMUM_QUEUE_LENGTH);

  Tasks := TObjectList<TScheduledTask>.Create();
  Tasks.ElementManager := TReferenceCounter<TScheduledTask>.Create();

  TaskGroups := TObjectList<TScheduledTaskGroup>.Create();
  TaskGroups.ElementManager := TReferenceCounter<TScheduledTaskGroup>.Create();

  TaskPools := TObjectList<TTaskThreadPool>.Create();
  TaskPools.Add(TTaskThreadPool.Create(TTask, TInteger32Interval.New(5, 10), MAXIMUM_QUEUE_LENGTH));
end;

destructor TTaskSchedulerThread.Destroy();
var
  RecurringTaskExecutor: TThread;
begin
  for RecurringTaskExecutor in RecurringTaskExecutors do
  begin
    RecurringTaskExecutor.Terminate();
    RecurringTaskExecutor.WaitFor(TWaitableObject.INFINITE);
  end;

  RecurringTaskExecutors.Free();
  TaskPools.Free();
  TerminationEvent.Free();
  AddLock.Free();
  StatusLock.Free();
  Tasks.Free();
  TaskGroups.Free();
  Statuses.Free();
  Timer.Free();
  EventQueue.Free();

  inherited Destroy();
end;

procedure TTaskSchedulerThread.Execute();
var
  TaskPool:        TTaskThreadPool;
  Object_:         TWaitableObject;
  WaitableObjects: TWaitableObjectGroup;
begin
  for TaskPool in TaskPools do
    TaskPool.Pool.StatusQueue := EventQueue;

  while not Terminated do
  begin
    WaitableObjects := TWaitableObjectGroup.Create();
    WaitableObjects.Add(TerminationEvent);
    WaitableObjects.Add(EventQueue);

    if Tasks.Count > 0 then
    begin
      Timer.Schedule(500 * 1000 * 10);
      WaitableObjects.Add(Timer);
    end;

    Object_ := WaitableObjects.WaitForAny(TWaitableObject.INFINITE);
    WaitableObjects.Free();

    if TerminationEvent.IsSignaled then
      FTerminated := True
    else
    begin
      if Object_ = EventQueue then
        HandleEvents();

      HandleScheduledStop();
      HandleUpdateStatuses();
    end;
  end;
end;

function TTaskSchedulerThread.GetPoolForTask(Task: TTask): TTaskExecutionThreadPool;
var
  TaskPool:  TTaskThreadPool;
  TaskClass: TTaskClass;
begin
  TaskPool  := nil;
  TaskClass := TTaskClass(Task.ClassType);

  while TaskPool = nil do
  begin
    TaskPool  := TaskPools.Find(TTaskThreadPool.TWithClass.Create(TaskClass));
    TaskClass := TTaskClass(TaskClass.ClassParent);
  end;

  Result := TaskPool.Pool;
end;

procedure TTaskSchedulerThread.HandleEvent(Event: TEvent);
begin
  if Event is TTaskScheduledEvent then
    HandleTaskScheduled(Event as TTaskScheduledEvent)
  else if Event is TTaskStartedEvent then
    HandleTaskStarted(Event as TTaskStartedEvent)
  else if Event is TTaskFinishedEvent then
    HandleTaskFinished(Event as TTaskFinishedEvent)
  else if Event is TTaskGroupScheduledEvent then
    HandleTaskGroupScheduled(Event as TTaskGroupScheduledEvent)
  else if Event is TRecurringTaskStartedEvent then
    HandleRecurringTaskStarted(Event as TRecurringTaskStartedEvent)
  else if Event is TRecurringTaskScheduledEvent then
    HandleRecurringTaskScheduled(Event as TRecurringTaskScheduledEvent)
  else if Event is TTaskNodeUnscheduledEvent then
    HandleUnschedule(Event as TTaskNodeUnscheduledEvent);
end;

procedure TTaskSchedulerThread.HandleEvents();
var
  Event: TEvent;
begin
  repeat
    Event := EventQueue.Dequeue();

    HandleEvent(Event);
    Event.Free();
  until not EventQueue.WaitFor(0);
end;

procedure TTaskSchedulerThread.HandleRecurringTaskScheduled(TaskScheduled: TRecurringTaskScheduledEvent);
var
  ScheduledTask: TScheduledTask;
begin
  ScheduledTask := TaskScheduled.ScheduledTask;
  ScheduledTask.State     := TTaskState.Scheduled;
  ScheduledTask.StartTime := TaskScheduled.Instant;
end;

procedure TTaskSchedulerThread.HandleRecurringTaskStarted(TaskStarted: TRecurringTaskStartedEvent);
var
  Thread:        TRecurringTaskExecutionThread;
  ScheduledTask: TScheduledTask;
  Current:       TGregorianInstant;
  Duration:      TGregorianDuration;
begin
  ScheduledTask := TaskStarted.ScheduledTask;
  ScheduledTask.State := TTaskState.Scheduled;

  Current := TGregorianCalendar.CurrentInstant_Local();
  Current.AddReference();

  Duration := TGregorianCalendar.MilliSecondsToDuration(TaskStarted.Interval);
  Duration.AddReference();

  ScheduledTask.StartTime := TGregorianCalendar.AddDuration(Current, Duration);

  Current.ReleaseReference();
  Duration.ReleaseReference();

  Thread := TRecurringTaskExecutionThread.Create(ScheduledTask, TaskStarted.Interval);
  Thread.StatusQueue := EventQueue;
  Thread.Resume();

  Tasks.Add(ScheduledTask);
  RecurringTaskExecutors.Add(Thread);
end;

procedure TTaskSchedulerThread.HandleScheduledStop();
var
  ScheduledGroup: TScheduledTaskGroup;
  StopAfter:      TGregorianInstant;
  Now:            TGregorianInstant;
begin
  Now := TGregorianCalendar.CurrentInstant_Local();
  Now.AddReference();

  try
    for ScheduledGroup in TaskGroups do
    begin
      // TODO: We have to properly handle the following race condition that can occur when the user updates TTaskGroup.StopAfter
      //       while it is being evaluated here.
      StopAfter := ScheduledGroup.TaskGroup.StopAfter;
      StopAfter.AddReference();

      try
        if (StopAfter <> nil) and (Now.CompareTo(StopAfter) > sZero) then
          UnscheduleTaskGroup(ScheduledGroup.TaskGroup);
      finally
        StopAfter.ReleaseReference();
      end;
    end;
  finally
    Now.ReleaseReference();
  end;
end;

procedure TTaskSchedulerThread.HandleTaskFinished(TaskFinished: TTaskFinishedEvent);
var
  ScheduledTask: TScheduledTask;
begin
  ScheduledTask := TaskFinished.ScheduledTask;
  ScheduledTask.AddReference();
  ScheduledTask.State := TTaskState.Finished;

  Tasks.Remove(ScheduledTask);

  UpdateDependencies(ScheduledTask.Task);
  UpdateTaskGroups();

  ScheduledTask.ReleaseReference();
end;

procedure TTaskSchedulerThread.HandleTaskScheduled(TaskScheduled: TTaskScheduledEvent);
var
  ScheduledTask: TScheduledTask;
begin
  ScheduledTask := TaskScheduled.ScheduledTask;
  ScheduledTask.State := TTaskState.WaitingForDependencies;

  Tasks.Add(ScheduledTask);
  QueueIfPossible(ScheduledTask);
end;

procedure TTaskSchedulerThread.HandleTaskGroupScheduled(TaskGroupScheduled: TTaskGroupScheduledEvent);
var
  ScheduledTask:      TScheduledTask;
  ScheduledTaskGroup: TScheduledTaskGroup;
begin
  ScheduledTaskGroup := TaskGroupScheduled.ScheduledTaskGroup;

  for ScheduledTask in ScheduledTaskGroup.Tasks do
  begin
    ScheduledTask.State := TTaskState.WaitingForDependencies;
    Tasks.Add(ScheduledTask);
  end;

  TaskGroups.Add(ScheduledTaskGroup);

  for ScheduledTask in ScheduledTaskGroup.Tasks do
    QueueIfPossible(ScheduledTask);
end;

procedure TTaskSchedulerThread.HandleTaskStarted(TaskStarted: TTaskStartedEvent);
var
  ScheduledTask: TScheduledTask;
begin
  ScheduledTask := TaskStarted.ScheduledTask;
  ScheduledTask.State     := TTaskState.Executing;
  ScheduledTask.StartTime := TGregorianCalendar.CurrentInstant_Local();
end;

procedure TTaskSchedulerThread.HandleUpdateStatuses();
var
  CurrentInstant:     TGregorianInstant;
  GroupedTasks:       TList<TScheduledTask>;
  GroupedStatuses:    TList<TTaskStatus>;
  GroupStatus:        TTaskStatus;
  Status:             TTaskStatus;
  StatusMap:          TMap<TScheduledTask, TTaskStatus>;
  ScheduledTaskGroup: TScheduledTaskGroup;
  ScheduledTask:      TScheduledTask;
  SummedProgress:     TProgress;
  Task:               TTask;
  Statuses:           TList<TTaskStatus>;
begin
  Statuses := TObjectList<TTaskStatus>.Create();
  Statuses.Capacity := Tasks.Count + TaskGroups.Count;

  CurrentInstant := TGregorianCalendar.CurrentInstant_Local();
  CurrentInstant.AddReference();

  StatusMap := TObjectHashMap<TScheduledTask, TTaskStatus>.Create();
  StatusMap.KeyManager := TReferenceCounter<TScheduledTask>.Create();

  GroupedTasks := TObjectList<TScheduledTask>.Create();
  GroupedTasks.ElementManager := TReferenceCounter<TScheduledTask>.Create();

  GroupedStatuses := TObjectList<TTaskStatus>.Create();
  GroupedStatuses.ElementManager := TReferenceUser<TTaskStatus>.Create();

  for ScheduledTask in Tasks do
  begin
    Task := ScheduledTask.Task;

    Status := TTaskStatus.Create();
    Status.Name      := Task.ToText();
    Status.State     := ScheduledTask.State;
    Status.StartTime := ScheduledTask.StartTime;
    Status.Owner     := Task;

    if Task is TControllableTask then
    begin
      Status.HasProgress := True;
      Status.Progress    := (Task as TControllableTask).GetProgress();
    end;

    if Status.State = TTaskState.Executing then
      Status.TimeFromStart := TGregorianCalendar.TimeBetween(Status.StartTime, CurrentInstant)
    else if Status.State = TTaskState.Scheduled then
      Status.TimeFromStart := TGregorianCalendar.TimeBetween(CurrentInstant, Status.StartTime);

    StatusMap[ScheduledTask] := Status;
  end;

  for ScheduledTaskGroup in TaskGroups do
  begin
    GroupStatus := TTaskStatus.Create();
    GroupStatus.Name        := ScheduledTaskGroup.TaskGroup.ToText();
    GroupStatus.HasProgress := True;
    GroupStatus.Owner       := ScheduledTaskGroup.TaskGroup;

    GroupedStatuses.Add(GroupStatus);

    if ScheduledTaskGroup.Tasks.Contains(TScheduledTask.TWithState.Create(TTaskState.Executing)) then
      GroupStatus.State := TTaskState.Executing
    else if ScheduledTaskGroup.Tasks.Contains(TScheduledTask.TWithState.Create(TTaskState.InQueue)) then
      GroupStatus.State := TTaskState.InQueue
    else
      GroupStatus.State := TTaskState.WaitingForDependencies;

    SummedProgress.Step  := 0;
    SummedProgress.Total := 0;

    for ScheduledTask in ScheduledTaskGroup.Tasks do
    begin
      if (ScheduledTask.StartTime <> nil) and ((GroupStatus.StartTime = nil) or (ScheduledTask.StartTime.CompareTo(GroupStatus.StartTime) = sNegative)) then
        GroupStatus.StartTime := ScheduledTask.StartTime;

      Status := StatusMap[ScheduledTask];

      if Status <> nil then
      begin
        GroupedStatuses.Add(Status);
        GroupedTasks.Add(ScheduledTask);

        if Status.HasProgress then
          SummedProgress := SummedProgress + Status.Progress
        else if ScheduledTask.State <> TTaskState.Finished then
          SummedProgress := SummedProgress + 0
        else
          SummedProgress := SummedProgress + 1
      end
      else
      begin
        if ScheduledTask.Task is TControllableTask then
          SummedProgress := SummedProgress + (ScheduledTask.Task as TControllableTask).GetProgress()
        else
          SummedProgress := SummedProgress + 1;
      end;
    end;

    if GroupStatus.StartTime <> nil then
      GroupStatus.TimeFromStart := TGregorianCalendar.TimeBetween(GroupStatus.StartTime, CurrentInstant);

    GroupStatus.Progress := SummedProgress;
  end;

  for ScheduledTask in Tasks do
    if not GroupedTasks.Contains(ScheduledTask) then
      Statuses.Add(StatusMap[ScheduledTask]);

  Statuses.AddAll(GroupedStatuses);

  CurrentInstant.ReleaseReference();
  GroupedTasks.Free();
  GroupedStatuses.Free();
  StatusMap.Free();

  StatusLock.Acquire();

  try
    Self.Statuses := Statuses;
  finally
    StatusLock.Release();
  end;
end;

procedure TTaskSchedulerThread.QueueIfPossible(ScheduledTask: TScheduledTask);
var
  Pool: TTaskExecutionThreadPool;
begin
  if (ScheduledTask.State = TTaskState.WaitingForDependencies) and (ScheduledTask.Dependencies.Count = 0) then
  begin
    ScheduledTask.State := TTaskState.InQueue;
  
    Pool := GetPoolForTask(ScheduledTask.Task);
    Pool.Execute(ScheduledTask);
  end;
end;

procedure TTaskSchedulerThread.SetStatuses(const Value: TList<TTaskStatus>);
begin
  if Value <> Statuses then
  begin
    FStatuses.Free();
    FStatuses := Value;
  end;
end;

procedure TTaskSchedulerThread.Terminate();
begin
  inherited Terminate();

  TerminationEvent.Signal();
end;

procedure TTaskSchedulerThread.HandleUnschedule(UnscheduleEvent: TTaskNodeUnscheduledEvent);
begin
  if UnscheduleEvent.Node is TTask then
    UnscheduleTask(UnscheduleEvent.Node as TTask)
  else if UnscheduleEvent.Node is TTaskGroup then
    UnscheduleTaskGroup(UnscheduleEvent.Node as TTaskGroup);

  if UnscheduleEvent.CompletedEvent <> nil then
    UnscheduleEvent.CompletedEvent.Signal();
end;

procedure TTaskSchedulerThread.UnscheduleTask(Task: TTask);
var
  ControllableTask: TControllableTask;
begin
  if Task is TControllableTask then
  begin
    ControllableTask := Task as TControllableTask;
    ControllableTask.Controller.Stop();
  end;

  if RecurringTaskExecutors.Contains(TRecurringTaskExecutionThread.TWithTask.Create(Task)) then
  begin
    // TODO: We might want to do more than just remove the task from the list
    RecurringTaskExecutors.Remove(TRecurringTaskExecutionThread.TWithTask.Create(Task));
    Tasks.Remove(TScheduledTask.TWithTask.Create(Task));
  end;
end;

procedure TTaskSchedulerThread.UnscheduleTaskGroup(Group: TTaskGroup);
var
  Registration: TTaskRegistration;
begin
  for Registration in Group.Tasks do
    UnscheduleTask(Registration.Task);
end;

procedure TTaskSchedulerThread.UpdateDependencies(Task: TTask);
var
  DependentTask: TScheduledTask;
begin
  for DependentTask in Tasks do
  begin
    DependentTask.Dependencies.Remove(Task);
    QueueIfPossible(DependentTask);
  end;
end;

procedure TTaskSchedulerThread.UpdateTaskGroups();
var
  TaskGroup:  TScheduledTaskGroup;
  TaskGroups: TList<TScheduledTaskGroup>;
begin
  TaskGroups := TObjectList<TScheduledTaskGroup>.Create();
  TaskGroups.ElementManager := TReferenceCounter<TScheduledTaskGroup>.Create();
  TaskGroups.AddAll(Self.TaskGroups);

  for TaskGroup in TaskGroups do
  begin
    if TaskGroup.Tasks.MatchesAll(TScheduledTask.TWithState.Create(TTaskState.Finished)) then
      Self.TaskGroups.Remove(TaskGroup);
  end;

  TaskGroups.Free();
end;

{ TTaskThreadPool }

constructor TTaskThreadPool.Create(TaskClass: TTaskClass; const ConcurrencyRange: TInteger32Interval; MaximumQueueSize: TInteger32);
begin
  inherited Create();

  Self.TaskClass := TaskClass;
  Pool := TTaskExecutionThreadPool.Create(ConcurrencyRange, MaximumQueueSize);
end;

destructor TTaskThreadPool.Destroy();
begin
  Pool.Free();

  inherited Destroy();
end;

{ TTaskThreadPool.TWithClass }

function TTaskThreadPool.TWithClass.Matches(const Pool: TTaskThreadPool): TBoolean;
begin
  Result := Pool.TaskClass = ComparisonValue;
end;

end.