WebServer

Unit
Source
Symbols

Symbol	Description
TWebServer	Serves one or more `TWebSite` on a `THttpServer`
TWebServerRequestHandler	Handler forwarding a `THttpRequest` to the `TWebServer`
TWebSiteInformation	Resolved website information based on a request
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
///////////////////////////////////////////////////////////////////////////
//                                                                       //
//  Copyright (c) 2015 by Charta Software B.V.                           //
//  All rights reserved                                                  //
//                                                                       //
//  Version:  1.7.0.83525                                                //
//  Web site: https://pascal.chartasoftware.com/                         //
//                                                                       //
//  This code and information are provided "as is" without warranty of   //
//  any kind. Dissemination of this information or reproduction of       //
//  this material is strictly forbidden unless prior written permission  //
//  is obtained from Charta Software B.V..                               //
//                                                                       //
///////////////////////////////////////////////////////////////////////////

unit WebServer;

interface

uses
  Collection.Set_,
  Http.Request,
  Http.Request.Handler,
  Http.Response,
  Http.Server,
  Socket.Address.Internet,
  Socket.Secure.Layer.Security.Provider,
  Text,
  Uri,
  WebSite,
  WebSite.List,
  WebSite.Request;

type
  TWebSiteInformation = class(TObject)
  public
    WebSite:     TWebSite;
    WebSiteRoot: TUri;
    Path:        TUriPath;
    Domain:      TText;
  end;

  TWebServer = class(TObject)
  protected
    SecurityProvider: TSecurityProvider;

    function    CreateSecurityProvider(): TSecurityProvider; virtual;

    function    RedirectToCanonicalUri(Request: THttpRequest; WebSiteInformation: TWebSiteInformation): THttpResponse;

    function    HandleRequest(Request: THttpRequest): THttpResponse; virtual;
    function    HandleNotFoundRequest(Request: THttpRequest): THttpResponse;

    function    CreateWebSiteRequest(Request: THttpRequest; WebSiteInformation: TWebSiteInformation): TWebSiteRequest; virtual;
    function    GetWebSiteInformationForRequest(Request: THttpRequest): TWebSiteInformation; virtual;

    function    TranslateSocketAddress(SocketAddress: TInternetSocketAddress): TInternetSocketAddress;
    function    GetSocketAddresses(): TSet<TInternetSocketAddress>;

  public
    HttpServer: THttpServer;
    WebSites:   TSynchronizedWebSiteList;

    constructor Create(); virtual;
    destructor  Destroy(); override;

    function    GetMainWebSite(): TWebSite; virtual;

    procedure   Start();
  end;

  TWebServerRequestHandler = class(THttpRequestHandler)
  public
    WebServer: TWebServer;

    constructor Create(WebServer: TWebServer); virtual;

    function    HandleRequest(Request: THttpRequest): THttpResponse; override;
  end;

implementation

uses
  Collection.Set_.Sorted.List,
  Http.Method,
  Http.Request.Handler.Profiling,
  Http.Response.Text,
  Http.Status,
  Integer._32,
  Internet.MediaType.Text,
  Object_.Reference.Counter,
  Platform,
  Socket,
  Socket.Secure.Layer.Security.Provider.Static,
  Socket.Secure.Server,
  Socket.Server,
  Sql.Database,
  WebSite.Request.Handler.Logging,
  WebSite.Request.Handler.SessionHandling;

{ TWebServer }

constructor TWebServer.Create();
begin
  inherited Create();

  HttpServer := THttpServer.Create();
  HttpServer.RequestHandler := TProfilingHttpRequestHandler.Create(TWebServerRequestHandler.Create(Self));

  WebSites := TSynchronizedWebSiteList.Create(TWebSiteList.Create());
end;

function TWebServer.CreateSecurityProvider(): TSecurityProvider;
begin
  Result := TStaticSecurityProvider.Create(GetMainWebSite.Security);
end;

function TWebServer.CreateWebSiteRequest(Request: THttpRequest; WebSiteInformation: TWebSiteInformation): TWebSiteRequest;
begin
  Result := TWebSiteRequest.Create();
  Result.HttpRequest := Request;
  Result.Path        := WebSiteInformation.Path;
  Result.Domain      := WebSiteInformation.Domain;
  Result.UriProducer.Configure(WebSiteInformation.WebSiteRoot);
end;

destructor TWebServer.Destroy();
begin
  SecurityProvider.Free();
  WebSites.Free();
  HttpServer.Free();

  inherited Destroy();
end;

function TWebServer.GetMainWebSite(): TWebSite;
begin
  Result := WebSites[0];
end;

function TWebServer.GetSocketAddresses(): TSet<TInternetSocketAddress>;
var
  i:       TInteger32;
  WebSite: TWebSite;
begin
  Result := TSortedListSet<TInternetSocketAddress>.Create();
  Result.ElementManager := TReferenceCounter<TInternetSocketAddress>.Create();
  Result.Comparator     := TInternetSocketAddress.TCompare.Instance;

  for i := 0 to WebSites.Count - 1 do
  begin
    WebSite := WebSites[i];
    Result.Add(WebSite.ServerSettings.SocketAddress);
  end;
end;

function TWebServer.GetWebSiteInformationForRequest(Request: THttpRequest): TWebSiteInformation;
var
  WebSiteRoot: TUri;
begin
  Result := TWebSiteInformation.Create();
  Result.WebSite := GetMainWebSite();
  Result.Domain  := '';

  Result.Path := Request.RequestLine.RequestUri.Path;
  Result.Path.RootType := TUriRootType.Relative;

  WebSiteRoot := TUri.New();
  WebSiteRoot.Path.RootType := TUriRootType.Absolute;

  if Request.ClientSocket.Security = ssSecureSocketLayer then
    WebSiteRoot.Scheme := 'https'
  else
    WebSiteRoot.Scheme := 'http';

  WebSiteRoot.Authority := Request.Host;
  Result.WebSiteRoot := WebSiteRoot;
end;

function TWebServer.HandleNotFoundRequest(Request: THttpRequest): THttpResponse;
var
  TextResponse: THttpTextResponse;
begin
  TextResponse := THttpTextResponse.Create();
  TextResponse.Entity.ContentType := TMediaTypeTextHtml.Create();
  TextResponse.StatusLine.Status := THttpStatus.ClientErrorNotFound;
  TextResponse.Text := 'The requested website could not be found';

  Result := TextResponse;
end;

function TWebServer.HandleRequest(Request: THttpRequest): THttpResponse;
var
  WebSiteInformation:     TWebSiteInformation;
  WebSite:                TWebSite;
  Database:               TSqlDatabase;
  WebSiteRequest:         TWebSiteRequest;
  Handler:                TWebSiteWebSiteRequestHandler;
  LoggingHandler:         TLoggingWebSiteRequestHandler;
  SessionHandlingHandler: TSessionHandlingWebSiteRequestHandler;
begin
  WebSiteInformation := GetWebSiteInformationForRequest(Request);

  if WebSiteInformation <> nil then
  begin
    WebSite := WebSiteInformation.WebSite;

    if
      (WebSiteInformation.WebSiteRoot.ToText() <> WebSite.Uri.ToText())
      and (
        WebSiteInformation.Path.IsEmpty()
        or (WebSiteInformation.Path[0] <> 'Status') // TODO: We should check for the Status module here
      )
    then
      Result := RedirectToCanonicalUri(Request, WebSiteInformation)
    else
    begin
      // TODO: We should remove the following check for the Resource module
      if WebSiteInformation.Path.IsEmpty() or (WebSiteInformation.Path[0] <> 'Resource') then
        Database := WebSite.DatabaseConnector.OpenConnection()
      else
        Database := nil;

      try
        WebSiteRequest := CreateWebSiteRequest(Request, WebSiteInformation);
        WebSiteRequest.SqlDatabase := Database;

        try
          ActiveWebSiteRequest := WebSiteRequest;

          try
            Handler := TWebSiteWebSiteRequestHandler.Create(WebSiteRequest);
            Handler.WebSite := WebSite;

            LoggingHandler := TLoggingWebSiteRequestHandler.Create(WebSiteRequest, Handler);
            LoggingHandler.DatabaseConnector := WebSite.DatabaseConnector;

            SessionHandlingHandler := TSessionHandlingWebSiteRequestHandler.Create(WebSiteRequest, LoggingHandler);
            SessionHandlingHandler.AddReference();
            SessionHandlingHandler.SessionManager := WebSite.SessionManager;
            SessionHandlingHandler.CookieName     := 'CHARTA_WEB_SESSION_ID';

            try
              Result := SessionHandlingHandler.HandleRequest();
            finally
              SessionHandlingHandler.ReleaseReference();
            end;
          finally
            ActiveWebSiteRequest := nil;
          end;
        finally
          WebSiteRequest.Free();
        end;
      finally
        if Database <> nil then
          WebSite.DatabaseConnector.CloseConnection(Database);
      end;
    end;
  end
  else
    Result := HandleNotFoundRequest(Request);

  WebSiteInformation.Free();
end;

function TWebServer.RedirectToCanonicalUri(Request: THttpRequest; WebSiteInformation: TWebSiteInformation): THttpResponse;
var
  TextResponse: THttpTextResponse;
  Uri:          TUri;
begin
  if Request.RequestLine.Method = THttpMethod.Get then
  begin
    Uri := WebSiteInformation.WebSite.Uri;
    Uri.Path.Add(WebSiteInformation.Path);
    Uri.Parameters := Request.RequestLine.RequestUri.Parameters;

    TextResponse := THttpTextResponse.Create();
    TextResponse.StatusLine.Status := THttpStatus.RedirectionMovedPermanently;
    TextResponse.Location := Uri;

    Result := TextResponse;
  end
  else
  begin
    TextResponse := THttpTextResponse.Create();
    TextResponse.StatusLine.Status := THttpStatus.ClientErrorMethodNotAllowed;

    Result := TextResponse;
  end;
end;

procedure TWebServer.Start();
var
  Socket:              TServerSocket;
  SecureSocket:        TSecureServerSocket;
  WebSite:             TWebSite;
  SocketAddresses:     TSet<TInternetSocketAddress>;
  SocketAddress:       TInternetSocketAddress;
  TranslatedAddress:   TInternetSocketAddress;
  TranslatedAddresses: TSet<TInternetSocketAddress>;
begin
  SocketAddresses := GetSocketAddresses();

  TranslatedAddresses := TSortedListSet<TInternetSocketAddress>.Create();
  TranslatedAddresses.ElementManager := TReferenceCounter<TInternetSocketAddress>.Create();
  TranslatedAddresses.Comparator     := TInternetSocketAddress.TCompare.Instance;

  for SocketAddress in SocketAddresses do
    TranslatedAddresses.Add(TranslateSocketAddress(SocketAddress));

  for TranslatedAddress in TranslatedAddresses do
  begin
    Socket := TPlatform.Instance.CreateServerSocket(TranslatedAddress);
    Socket.Bind();

    HttpServer.ServerSockets.Add(Socket);
  end;

  SocketAddresses.Free();
  TranslatedAddresses.Free();

  WebSite := GetMainWebSite();

  if WebSite.ServerSettings.SecureSocketEnabled then
  begin
    TranslatedAddress := TranslateSocketAddress(WebSite.ServerSettings.SecureSocketAddress);
    TranslatedAddress.AddReference();

    SecurityProvider := CreateSecurityProvider();

    SecureSocket := TSecureServerSocket.Create(TPlatform.Instance.CreateServerSocket(TranslatedAddress));
    SecureSocket.SecurityProvider := SecurityProvider;
    SecureSocket.Bind();

    HttpServer.ServerSockets.Add(SecureSocket);
    TranslatedAddress.ReleaseReference();
  end;

  HttpServer.Start();
end;

function TWebServer.TranslateSocketAddress(SocketAddress: TInternetSocketAddress): TInternetSocketAddress;
var
  TranslatedAddress: TInternetSocketAddress;
begin
  Result := SocketAddress;

  if GetMainWebSite().IpRouting <> nil then
  begin
    TranslatedAddress := GetMainWebSite().IpRouting.Incoming[SocketAddress];

    if TranslatedAddress <> nil then
      Result := TranslatedAddress;
  end;
end;

{ TWebServerRequestHandler }

constructor TWebServerRequestHandler.Create(WebServer: TWebServer);
begin
  inherited Create();

  Self.WebServer := WebServer;
end;

function TWebServerRequestHandler.HandleRequest(Request: THttpRequest): THttpResponse;
begin
  Result := WebServer.HandleRequest(Request);
end;

end.