WebServer.Application

Unit
Source
Symbols

Symbol	Description
TAddHttpExchangeTask	Task for adding an `THttpExchange` to a log and notifying its models
THttpExchangeListener	Listener for `THttpExchangeExecutedEvent`
THttpLogAction	Action displaying the log of `THttpExchange` served by the `TWebServerApplication`
TInstallServiceAction	Install the `TWebServerApplication` as a Windows service
TServiceAction	Base action for Windows services
TUninstallServiceAction	Uninstall the `TWebServerApplication` as a Windows service
TValidateDatabaseAction
TWebServerApplication	Base application for running a `TWebServer`
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
///////////////////////////////////////////////////////////////////////////
//                                                                       //
//  Copyright (c) 2015 by Charta Software B.V.                           //
//  All rights reserved                                                  //
//                                                                       //
//  Version:  1.7.0.83525                                                //
//  Web site: https://pascal.chartasoftware.com/                         //
//                                                                       //
//  This code and information are provided "as is" without warranty of   //
//  any kind. Dissemination of this information or reproduction of       //
//  this material is strictly forbidden unless prior written permission  //
//  is obtained from Charta Software B.V..                               //
//                                                                       //
///////////////////////////////////////////////////////////////////////////

unit WebServer.Application;

interface

uses
  Application.Default,
  Application.Default.Action,
  Boolean,
  Collection.List,
  Dom.Element,
  Event,
  Http.Exchange,
  Object_.Base,
  Service,
  Sql.Connection.Settings,
  Table.Model,
  Task,
  UserInterface.Control.Panel.Stack,
  UserInterface.Control.Table,
  UserInterface.Object_.Action.Factory,
  Value,
  WebServer;

type
  THttpExchangeListener = class(TBaseObject)
  private
    Models: TList<TTableModel>;

  public
    Exchanges: TList<THttpExchange>;

    constructor Create(); override;
    destructor  Destroy(); override;

    procedure   Add(Model: TTableModel);

    function    HandleEvent(Event: TEvent): TBoolean; override;
  end;

  TWebServerApplication = class(TDefaultApplication)
  protected
    WebServer:        TWebServer;
    Exchanges:        TList<THttpExchange>;
    ExchangeListener: THttpExchangeListener;

    function    GetApplicationExplorerRoot(): TValue; override;
    function    CreateWebServer(): TWebServer; virtual; abstract;

    function    CreateObjectActionFactory(): TObjectActionFactory; override;

    procedure   Initialize(Configuration: TDomElement); override;
    procedure   InitializeControls(); override;

    procedure   AddToolBarButtons(ToolBar: THorizontalStackPanel); override;

    procedure   CreateWebSitesTable();

    procedure   CheckAndPerformCommandLineArguments();
    procedure   SetUpSqlDatabase(ConnectionSettings: TSqlConnectionSettings);

    function    CreateHttpLogControl(): TTableControl;
    procedure   ShowHttpLog();

  protected
    class var
      Service: TService;

    class procedure PostProcessService(Service: TService);
    class function  HandleService(): TBoolean;
    class function  CreateService(): TService; virtual; 

  public
    constructor Create(); override;
    destructor  Destroy(); override;

  public
    class procedure Main(); override;
  end;

  THttpLogAction = class(TApplicationAction<TWebServerApplication>)
  protected
    procedure   Execute(); override;
  end;

  TServiceAction = class(TApplicationAction<TWebServerApplication>)
  protected
    Service: TService;

  public
    constructor Create(WebServerApplication: TWebServerApplication; Service: TService); reintroduce; virtual;
  end;

  TInstallServiceAction = class(TServiceAction)
  protected
    procedure   Execute(); override;
  end;

  TUninstallServiceAction = class(TServiceAction)
  protected
    procedure   Execute(); override;
  end;

  TValidateDatabaseAction = class(TApplicationAction<TWebServerApplication>)
  protected
    procedure   Execute(); override;
  end;

  TAddHttpExchangeTask = class(TTask)
  protected
    Target:   TList<THttpExchange>;
    Exchange: THttpExchange;
    Models:   TList<TTableModel>;

  public
    constructor Create(Target: TList<THttpExchange>; Exchange: THttpExchange; Models: TList<TTableModel>); reintroduce; virtual;
    destructor  Destroy(); override;

    procedure   Execute(); override;
  end;

implementation

uses
  Configuration,
  Dictionary,
  Http.Exchange.Event,
  Integer._32,
  Integer._32.Interval,
  Object_.List,
  Object_.Reference,
  Object_.Reference.Counter,
  Object_.Reference.Type_,
  Process.Current,
  Sql,
  Sql.Database,
  Sql.Database.Connector,
  Sql.Database.Script.Manager,
  Sql.Database.Validator,
  Sql.Factory.Action,
  Sql.Schema.Information,
  Sql.Table.Set_.Manager,
  Sql.Table.Set_.Registration,
  Table.Header.Model,
  Table.Header.Model.Event,
  Task.Scheduler,
  Value.Path,
  WebSite.List.TableModel,
  Windows.Service,
  Windows.Service.Manager;

{ TWebServerApplication }

procedure TWebServerApplication.AddToolBarButtons(ToolBar: THorizontalStackPanel);
begin
  inherited AddToolBarButtons(ToolBar);

  ToolBar.AddControl(CreateButton('HTTP log', THttpLogAction.Create(Self)));

  if TWebServerApplication.Service <> nil then
  begin
    ToolBar.AddControl(CreateButton('Install service', TInstallServiceAction.Create(Self, TWebServerApplication.Service)));
    ToolBar.AddControl(CreateButton('Uninstall service', TUninstallServiceAction.Create(Self, TWebServerApplication.Service)));
  end;

  ToolBar.AddControl(CreateButton('Validate database', TValidateDatabaseAction.Create(Self)));
end;

procedure TWebServerApplication.CheckAndPerformCommandLineArguments();
var
  Parameters:         TDictionary;
  ConnectionSettings: TSqlConnectionSettings;
  Configuration:      TDomElement;
  DatabaseElement:    TDomElement;
begin
  Parameters := TCurrentProcess.Instance.CommandLine.Dictionary;

  if Parameters.KeyExists('setUpDatabase') then
  begin
    Configuration   := LoadDefaultConfiguration();
    DatabaseElement := Configuration.ElementForPath(['WebSite', 'Database']);

    if DatabaseElement <> nil then
    begin
      ConnectionSettings := TSqlConnectionSettings.CreateFromElement(DatabaseElement);
      ConnectionSettings.AddReference();

      SetUpSqlDatabase(ConnectionSettings);
      ConnectionSettings.ReleaseReference();
    end;

    Configuration.Free();
  end;
end;

constructor TWebServerApplication.Create();
begin
  inherited Create();

  Exchanges := TObjectList<THttpExchange>.Create();
  Exchanges.ElementManager := TReferenceCounter<THttpExchange>.Create();

  ExchangeListener := THttpExchangeListener.Create();
  ExchangeListener.Exchanges := Exchanges;
end;

function TWebServerApplication.CreateHttpLogControl(): TTableControl;
var
  Path:  TValuePath;
  Model: TTableModel;
begin
  Path := TValuePath.Create([TObjectReference.Create(Exchanges, TReferenceType.RefersTo)]);
  Path.AddReference();

  try
    Model := TableFactory.CreateTableModel(Path);
  finally
    Path.ReleaseReference();
  end;

  Result := TTableControl.Create();
  Result.RowHeadersControl.Width := 45;
  Result.Model   := Model;
  Result.Caption := 'HTTP log';

  ExchangeListener.Add(Model);
  WebServer.HttpServer.Listeners.Add(ExchangeListener);
end;

function TWebServerApplication.CreateObjectActionFactory: TObjectActionFactory;
begin
  Result := TSqlActionFactory.Create(inherited CreateObjectActionFactory());
end;

class function TWebServerApplication.CreateService(): TService;
begin
  Result := nil;
end;

procedure TWebServerApplication.CreateWebSitesTable();
var
  TableModel:   TSynchronizedWebSiteListTableModel;
  TableControl: TTableControl;
begin
  TableModel := TSynchronizedWebSiteListTableModel.Create();
  TableModel.WebSites := WebServer.WebSites;

  TableControl := TTableControl.Create();
  TableControl.Model   := TableModel;
  TableControl.Caption := 'Web sites';

  OpenControl(TableControl, True);
end;

destructor TWebServerApplication.Destroy();
begin
  Exchanges.Free();
  ExchangeListener.Free();
  WebServer.Free();
  TWebServerApplication.Service.Free();

  inherited Destroy();
end;

function TWebServerApplication.GetApplicationExplorerRoot(): TValue;
begin
  Result := TObjectReference.Create(WebServer.WebSites[0], TReferenceType.RefersTo);
end;

class function TWebServerApplication.HandleService(): TBoolean;
var
  Parameters:     TDictionary;
  WindowsService: TWindowsService;
begin
  TWebServerApplication.Service := CreateService();

  if TWebServerApplication.Service <> nil then
  begin
    PostProcessService(TWebServerApplication.Service);

    Parameters := TCurrentProcess.Instance.CommandLine.Dictionary;
    Result     := Parameters.GetTextValueWithDefault('type', 'graphical') = 'service';

    if Result then
    begin
      WindowsService := TWindowsService.Create();
      WindowsService.Service := TWebServerApplication.Service;
      WindowsService.Execute();
      WindowsService.Free();

      TWebServerApplication.Service.Free();
    end;
  end
  else
    Result := False;
end;

procedure TWebServerApplication.Initialize(Configuration: TDomElement);
begin
  inherited Initialize(Configuration);

  WebServer := CreateWebServer();
  WebServer.Start();
end;

procedure TWebServerApplication.InitializeControls();
begin
  inherited InitializeControls();

  if WebServer.WebSites.Count > 1 then
    CreateWebSitesTable()
  else
    Old_OpenControlForValue(GetApplicationExplorerRoot(), True);
end;

class procedure TWebServerApplication.Main();
begin
  if not HandleService() then
    inherited Main();
end;

class procedure TWebServerApplication.PostProcessService(Service: TService);
var
  Configuration:  TDomElement;
  ServiceElement: TDomElement;
begin
  Configuration := LoadDefaultConfiguration();

  if Configuration <> nil then
  begin
    ServiceElement := Configuration.ElementWithName('Service');

    if ServiceElement <> nil  then
    begin
      Service.Name        := ServiceElement.Attributes.Get('Name').AsText();
      Service.DisplayName := ServiceElement.Attributes.Get('DisplayName').AsText();
    end;
  end;

  Configuration.Free();
end;

procedure TWebServerApplication.SetUpSqlDatabase(ConnectionSettings: TSqlConnectionSettings);
var
  Database:                  TSqlDatabase;
  TableSetManager:           TSqlTableSetManager;
  ScriptManager:             TSqlDatabaseScriptManager;
  InformationSchemaSettings: TSqlConnectionSettings;
begin
  InformationSchemaSettings := ConnectionSettings.Copy();
  InformationSchemaSettings.AddReference();
  InformationSchemaSettings.DatabaseName := TSqlInformationSchema.DEFAULT_IDENTIFIER;

  Database := CreateSqlDatabase(InformationSchemaSettings);
  Database.Query(CreateDatabase(ConnectionSettings.DatabaseName));
  Database.Free();

  InformationSchemaSettings.ReleaseReference();

  Database := CreateSqlDatabase(ConnectionSettings);

  TableSetManager := TSqlTableSetManager.Create(Database);
  TableSetManager.CreateTableSetsFromRegistration(TableSetRegistration);
  TableSetManager.Free();

  ScriptManager := TSqlDatabaseScriptManager.Create();
  ScriptManager.RegisterScripts(TableSetRegistration);
  ScriptManager.SetupNew(Database);
  ScriptManager.Free();

  Database.Free();
end;

procedure TWebServerApplication.ShowHttpLog();
begin
  OpenControl(CreateHttpLogControl(), True);
end;

{ THttpLogAction }

procedure THttpLogAction.Execute();
begin
  Application.ShowHttpLog();
end;

{ THttpExchangeListener }

procedure THttpExchangeListener.Add(Model: TTableModel);
begin
  Models.Add(Model);
end;

constructor THttpExchangeListener.Create();
begin
  inherited Create();

  Models := TObjectList<TTableModel>.Create();
  Models.ElementManager := TReferenceCounter<TTableModel>.Create();
end;

destructor THttpExchangeListener.Destroy();
begin
  Models.Free();

  inherited Destroy();
end;

function THttpExchangeListener.HandleEvent(Event: TEvent): TBoolean;
var
  Task: TAddHttpExchangeTask;
begin
  Result := Event is THttpExchangeExecutedEvent;

  if Result then
  begin
    Task := TAddHttpExchangeTask.Create(Exchanges, (Event as THttpExchangeExecutedEvent).Exchange, Models);
    TTaskScheduler.Instance.ExecuteInUserInterface(Task, TWaitType.DontWait);
  end;
end;

{ TAddHttpExchangeTask }

constructor TAddHttpExchangeTask.Create(Target: TList<THttpExchange>; Exchange: THttpExchange; Models: TList<TTableModel>);
begin
  inherited Create();

  Self.Target   := Target;
  Self.Exchange := Exchange;
  Self.Models   := Models;

  Exchange.AddReference();
end;

destructor TAddHttpExchangeTask.Destroy();
begin
  Exchange.ReleaseReference();

  inherited Destroy();
end;

procedure TAddHttpExchangeTask.Execute();
var
  i:        TInteger32;
  RowModel: TTableHeaderModel;
begin
  Target.Add(Exchange);

  for i := 0 to Models.Count - 1 do
  begin
    RowModel := Models[i].GetRowModel();
    RowModel.Listeners.DistributeEvent(TTableHeaderModelHeadersInsertedEvent.Create(RowModel, TInteger32Interval.NewSingleValue(Target.Count)));
  end;
end;

{ TInstallServiceAction }

procedure TInstallServiceAction.Execute();
var
  ServiceManager:    TWindowsServiceManager;
  RegisteredService: TRegisteredService;
begin
  RegisteredService := TRegisteredService.Create();
  RegisteredService.Name        := Service.Name;
  RegisteredService.DisplayName := Service.DisplayName;
  RegisteredService.Path        := TCurrentProcess.Instance.Path;
  RegisteredService.Arguments.Add('--type=service');

  ServiceManager := TWindowsServiceManager.Create();

  try
    ServiceManager.Install(RegisteredService);
  finally
    ServiceManager.Free();
  end;

  RegisteredService.Free();
end;

{ TUninstallServiceAction }

procedure TUninstallServiceAction.Execute();
var
  ServiceManager:    TWindowsServiceManager;
  RegisteredService: TRegisteredService;
begin
  RegisteredService := TRegisteredService.Create();
  RegisteredService.Name        := Service.Name;
  RegisteredService.DisplayName := Service.DisplayName;
  RegisteredService.Path        := TCurrentProcess.Instance.Path;

  ServiceManager := TWindowsServiceManager.Create();

  try
    ServiceManager.Uninstall(RegisteredService);
  finally
    ServiceManager.Free();
  end;

  RegisteredService.Free();
end;

{ TServiceAction }

constructor TServiceAction.Create(WebServerApplication: TWebServerApplication; Service: TService);
begin
  inherited Create(WebServerApplication);

  Self.Service := Service;
end;

{ TValidateDatabaseAction }

procedure TValidateDatabaseAction.Execute();
var
  Validator: TSqlDatabaseValidator;
begin
  Validator := TSqlDatabaseValidator.Create();

  Application.Old_OpenControlForValue(TObjectReference.Create(Validator.ValidationResults, TReferenceType.Owns), False);

  TTaskScheduler.Instance.Execute(Validator);
end;

end.