1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
| ///////////////////////////////////////////////////////////////////////////
// //
// Copyright (c) 2015 by Charta Software B.V. //
// All rights reserved //
// //
// Version: 1.7.0.83525 //
// Web site: https://pascal.chartasoftware.com/ //
// //
// This code and information are provided "as is" without warranty of //
// any kind. Dissemination of this information or reproduction of //
// this material is strictly forbidden unless prior written permission //
// is obtained from Charta Software B.V.. //
// //
///////////////////////////////////////////////////////////////////////////
unit WebSite.Control.Module;
interface
uses
Authorization.Level,
Collection.Map,
Dom.Attribute,
Dom.Element,
Html.Element,
Html.Element.Block,
Http.Response,
Http.Response.Html,
Http.Response.Pdf,
Http.Response.Xml,
Image.Raster,
StructuredDocument.Node,
StructuredDocument.Node.Localize,
Table.Model,
Text,
Uri,
UserInterface.Control,
UserInterface.Keyboard.Modifiers,
UserInterface.Mouse.Event,
Value,
WebSite.Control.Source,
WebSite.Control.Window,
WebSite.Module,
WebSite.Request,
WebSite.Request.Handler,
WebSite.Request.Handler.Default;
type
TControlEmbellishment = (ceNone, ceDefault, ceAssistantControls);
TControlWebSiteModule = class(TWebSiteModule)
protected
FSource: TControlSource;
FName: TText;
FTitle: TDocumentLocalize;
Windows: TMap<TControl, TWebSiteControlWindow>;
procedure SetSource(const Value: TControlSource);
procedure FreeWindows();
public
Embellishment: TControlEmbellishment;
constructor Create(const Name: TText; Title: TDocumentLocalize; Source: TControlSource); reintroduce; virtual;
destructor Destroy(); override;
function GetName(): TText; override;
function GetTitle(Request: TWebSiteRequest): TDocumentNode; override;
function CreateRequestHandler(Request: TWebSiteRequest): TWebSiteRequestHandler; override;
function GetMinimumAuthorizationLevel(Request: TWebSiteRequest): TAuthorizationLevel; override;
property Source: TControlSource read FSource write SetSource;
end;
TControlWebSiteRequestHandler = class(TDefaultWebSiteRequestHandler)
private
FTitle: TDocumentLocalize;
procedure SetTitle(const Value: TDocumentLocalize);
protected
function RenderToPdf(): THttpPdfResponse;
function RenderToRasterImage(): TRasterImage;
function RenderToImage(): THttpResponse;
function GetEffectiveUri(): TUri;
function LinkToControl(): THtmlDivision;
function RenderToHtml(): THttpHtmlResponse;
function GetKeyModifiers(Attributes: TDomAttributeMap): TKeyModifiers;
function HtmlToText(Element: THtmlElement): TText;
function TableModelToText(TableModel: TTableModel): TText;
function FocusedObjectToText(const FocusedObject: TValue): TText;
function ConvertToMouseEvent(Element: TDomElement): TMouseEvent;
procedure HandleEventElement(Element: TDomElement);
function HandleEventRequest(Element: TDomElement): THttpXmlResponse;
function HandleSetEditingRequest(Element: TDomElement): THttpXmlResponse;
function CreateXmlResponse(): THttpXmlResponse;
function HandleXmlRequest(): THttpResponse;
public
Control: TControl;
Window: TWebSiteControlWindow;
Uri: TUri;
destructor Destroy(); override;
function HandleRequest(): THttpResponse; override;
function GetTitle(): TDocumentNode; override;
property Title: TDocumentLocalize read FTitle write SetTitle;
end;
implementation
uses
Character.Encoding,
Color.Constants,
Drawing.Fill,
Exception,
FloatingPoint._64,
Geometry._2d.FloatingPoint64.Point,
Geometry._2d.Integer32.Point,
Geometry._2d.Integer32.Size,
Geometry._2d.Transformation.Affine,
Html,
Html.Document,
Html.Document.Writer,
Html.Element.Block.Table,
Http.Method,
Image.Raster.Png.Writer,
Integer._32,
Integer._32.Interval,
Integer._32.TextFormat,
Internet.MediaType.Application,
Internet.MediaType.Image,
Iterator,
Javascript,
Language.TranslationMap.Constants.General,
Object_.Base,
Object_.Map.Hash,
Object_.Reference,
Object_.Reference.Owner,
Pdf.Canvas,
Pdf.Document.Builder,
Pdf.Instruction,
Pdf.Object_.Complex.Page,
Stream.Input,
Stream.Output,
StructuredDocument.Compiler.Text,
Table.Cells,
Table.Header,
Table.Row,
Text.Stream.Output,
UserInterface.Control.Drawing,
UserInterface.Control.Mode,
UserInterface.Keyboard.Event,
UserInterface.Mouse,
Value.Path,
WebSite.Form.Language.TranslationMap,
WebSite.Language.TranslationMap,
WebSite.Menu.Control,
WebSite.Menu.Item,
Windows.Api.Kernel.DateTime,
Windows.Api.VirtualKeyCodes,
Windows.Gdi.Bitmap,
Windows.Gdi.Canvas,
Xml,
Xml.Writer;
{ TControlWebSiteModule }
constructor TControlWebSiteModule.Create(const Name: TText; Title: TDocumentLocalize; Source: TControlSource);
begin
inherited Create();
Windows := TObjectHashMap<TControl, TWebSiteControlWindow>.Create();
Windows.ValueManager := TReferenceOwner<TWebSiteControlWindow>.Create();
Embellishment := ceNone;
FName := Name;
FTitle := Title;
Self.Source := Source;
end;
function TControlWebSiteModule.CreateRequestHandler(Request: TWebSiteRequest): TWebSiteRequestHandler;
var
ControlHandler: TControlWebSiteRequestHandler;
Control: TControl;
Window: TWebSiteControlWindow;
begin
if ((Request.HttpRequest.Entity.ContentType = nil) or not (Request.HttpRequest.Entity.ContentType is TMediaTypeApplicationXml)) and (Request.GetParameters.Count = 0) then
Source.LinkedToControl(Request);
Control := Source.GetControl(Request);
Window := Windows[Control];
if Window = nil then
begin
Window := TWebSiteControlWindow.Create();
Window.Size := Control.Size;
case Embellishment of
ceNone:
Window.Control := Control;
ceDefault:
Window.Control := Control.Embellish();
ceAssistantControls:
begin
Window.Size := TInteger32Size.New(1000, 500);
Window.Control := (Control as TDrawingControl).EmbellishWithAssistantControls();
end;
end;
Windows[Control] := Window;
end;
ControlHandler := TControlWebSiteRequestHandler.Create(Request);
ControlHandler.Title := FTitle;
ControlHandler.Control := Control;
ControlHandler.Window := Window;
ControlHandler.Uri := Request.UriProducer.RelativeUri([GetName()], TUriResourceType.File_);
Result := ControlHandler;
end;
destructor TControlWebSiteModule.Destroy();
begin
FreeWindows();
Windows.Free();
Source.ReleaseReference();
inherited Destroy();
end;
procedure TControlWebSiteModule.FreeWindows();
var
MapEntry: TMapEntry<TControl, TWebSiteControlWindow>;
Control: TControl;
begin
for MapEntry in Windows do
begin
Control := MapEntry.Key;
Control.ParentControl.ChildControls.Remove(Control);
end;
end;
function TControlWebSiteModule.GetMinimumAuthorizationLevel(Request: TWebSiteRequest): TAuthorizationLevel;
begin
Result := TAuthorizationLevel.Public_;
end;
function TControlWebSiteModule.GetName(): TText;
begin
Result := FName;
end;
procedure TControlWebSiteModule.SetSource(const Value: TControlSource);
begin
if Value <> Source then
begin
Value.AddReference();
Source.ReleaseReference();
FSource := Value;
end;
end;
function TControlWebSiteModule.GetTitle(Request: TWebSiteRequest): TDocumentNode;
begin
Result := FTitle;
end;
{ TControlWebSiteRequestHandler }
function TControlWebSiteRequestHandler.ConvertToMouseEvent(Element: TDomElement): TMouseEvent;
var
Event: TText;
Button: TInteger32;
Mouse: TMouse;
ButtonEvent: TMouseButtonEvent;
WheelEvent: TMouseWheelEvent;
begin
Result := nil;
Event := Element.Name;
Mouse := Window.MouseManager.Mouse;
if Event = 'mouseMove' then
Result := TMouseMoveEvent.Create(Mouse)
else if (Event = 'mouseDown') or (Event = 'mouseUp') then
begin
Button := Element.Attributes.GetOptional('button').AsIntegerWithDefault(0);
if Event = 'mouseDown' then
ButtonEvent := TMouseButtonDownEvent.Create(Mouse)
else if Event = 'mouseUp' then
ButtonEvent := TMouseButtonUpEvent.Create(Mouse)
else
raise EException.Create('Unknown mouse button event: ' + Event);
ButtonEvent.Count := 1; // TODO: We have to accurately determine other counts as well
case Button of
0: ButtonEvent.Button := Mouse.Left;
1: ButtonEvent.Button := Mouse.Middle;
2: ButtonEvent.Button := Mouse.Right;
end;
Result := ButtonEvent;
end
else if Event = 'mouseWheel' then
begin
WheelEvent := TMouseWheelEvent.Create(Mouse);
WheelEvent.Delta := Element.Attributes.Get('delta').AsInteger();
Result := WheelEvent;
end;
Result.Position := TInteger32Point.New(Element.Attributes.Get('x').AsInteger(), Element.Attributes.Get('y').AsInteger());
Result.KeyModifiers := GetKeyModifiers(Element.Attributes);
end;
function TControlWebSiteRequestHandler.CreateXmlResponse(): THttpXmlResponse;
var
FocusedObject: TValuePath;
ImageUri: TUri;
Writer: TXmlWriter;
HintPosition: TInteger32Point;
begin
Result := THttpXmlResponse.Create();
Writer := Result.Writer;
Writer.IndentSize := 2;
Writer.WriteHeader();
Writer.StartElement('control');
if Window.Invalidated then
begin
ImageUri := GetEffectiveUri();
ImageUri.Parameters.Add('timestamp', GetTickCount());
Writer.StartElement('image');
Writer.WriteAttribute('uri', ImageUri.ToText());
Writer.EndElement();
end;
FocusedObject := Control.GetFocusedObject();
FocusedObject.AddReference();
try
Writer.StartElement('focusedObject');
if FocusedObject.Length > 0 then
Writer.WriteAttribute('value', FocusedObjectToText(FocusedObject.Last))
else
Writer.WriteAttribute('value', '');
Writer.EndElement();
finally
FocusedObject.ReleaseReference();
end;
HintPosition := Window.HintWindow.Position;
Writer.StartElement('hint');
Writer.WriteAttribute('value', FocusedObjectToText(Window.HintWindow.Value));
Writer.WriteAttribute('x', Integer32ToText(HintPosition.X));
Writer.WriteAttribute('y', Integer32ToText(HintPosition.Y));
Writer.EndElement();
Writer.EndElement();
end;
destructor TControlWebSiteRequestHandler.Destroy();
begin
Title.ReleaseReference();
inherited Destroy();
end;
function TControlWebSiteRequestHandler.FocusedObjectToText(const FocusedObject: TValue): TText;
var
Object_: TObject;
TableModel: TTableModel;
Path: TValuePath;
begin
if FocusedObject is THtmlElement then
Result := HtmlToText(FocusedObject as THtmlElement)
else if FocusedObject is TObjectReference then
begin
Object_ := (FocusedObject as TObjectReference).Value;
if Object_ is TDocumentLocalize then
Result := Request.Localizer.Text.Translate(Object_ as TDocumentLocalize)
else
begin
Path := TValuePath.Create([FocusedObject]);
Path.AddReference();
try
TableModel := Request.TableModelFactory.CreateTableModel(Path);
finally
Path.ReleaseReference();
end;
if TableModel <> nil then
begin
TableModel.AddReference();
Result := TableModelToText(TableModel);
TableModel.ReleaseReference();
end
else if Object_ is TBaseObject then
Result := (Object_ as TBaseObject).ToText()
else
Result := '';
end;
end
else if FocusedObject <> nil then
Result := FocusedObject.ToText()
else
Result := '';
end;
function TControlWebSiteRequestHandler.GetEffectiveUri(): TUri;
begin
if not Uri.IsEmpty() then
Result := Uri
else
Result := Request.UriProducer.RelativeUri([], TUriResourceType.File_);
end;
function TControlWebSiteRequestHandler.GetKeyModifiers(Attributes: TDomAttributeMap): TKeyModifiers;
begin
Result := [];
if Attributes.GetOptional('alt').AsBooleanWithDefault() then
Result := Result + [TKeyModifier.Alt];
if Attributes.GetOptional('control').AsBooleanWithDefault() then
Result := Result + [TKeyModifier.Control];
if Attributes.GetOptional('shift').AsBooleanWithDefault() then
Result := Result + [TKeyModifier.Shift];
end;
function TControlWebSiteRequestHandler.GetTitle(): TDocumentNode;
begin
Result := Title;
end;
procedure TControlWebSiteRequestHandler.HandleEventElement(Element: TDomElement);
var
Event: TText;
MouseEvent: TMouseEvent;
ControlForEvent: TControl;
KeyModifiers: TKeyModifiers;
KeyDownEvent: TKeyDownEvent;
KeyUpEvent: TKeyUpEvent;
KeyPressEvent: TKeyPressEvent;
begin
Event := Element.Name;
if (Event = 'mouseMove') or (Event = 'mouseDown') or (Event = 'mouseUp') or (Event = 'mouseWheel') then
begin
MouseEvent := ConvertToMouseEvent(Element);
MouseEvent.UpdateMouseState();
Window.Cursor.Position := MouseEvent.Position;
ControlForEvent := Window.MouseManager.ControlForEvent(Window, MouseEvent);
if (MouseEvent is TMouseButtonUpEvent) and (Window.MouseManager.ControlWithCapture = ControlForEvent) then
Window.MouseManager.ControlWithCapture := nil;
MouseEvent.Position := Window.ConvertPositionToDescendantPosition(MouseEvent.Position, ControlForEvent);
try
ControlForEvent.DistributeMouseEventUpHierarchy(MouseEvent);
finally
MouseEvent.Free();
end;
end
else if Event = 'mouseLeave' then
begin
MouseEvent := TMouseLeaveEvent.Create(Window.MouseManager.Mouse);
try
Control.HandleMouseEvent(MouseEvent);
finally
MouseEvent.Free();
end;
end
else
begin
KeyModifiers := GetKeyModifiers(Element.Attributes);
if Event = 'keyDown' then
begin
KeyDownEvent := TKeyDownEvent.Create(nil, KeyModifiers, TVirtualKey.ToKey(Element.Attributes.Get('keyCode').AsInteger()));
try
Control.KeyDown(KeyDownEvent);
finally
KeyDownEvent.Free();
end;
end
else if Event = 'keyUp' then
begin
KeyUpEvent := TKeyUpEvent.Create(nil, KeyModifiers, TVirtualKey.ToKey(Element.Attributes.Get('keyCode').AsInteger()));
try
Control.KeyUp(KeyUpEvent);
finally
KeyUpEvent.Free();
end;
end
else if Event = 'keyPress' then
begin
KeyPressEvent := TKeyPressEvent.Create(nil, KeyModifiers, Element.Attributes.Get('keyCode').AsInteger());
try
Control.KeyPress(KeyPressEvent);
finally
KeyPressEvent.Free();
end;
end;
end;
end;
function TControlWebSiteRequestHandler.HandleEventRequest(Element: TDomElement): THttpXmlResponse;
var
Iterator: TIterator<TDomElement>;
begin
Iterator := Element.CreateElementIterator();
while Iterator.IsValid() do
begin
HandleEventElement(Iterator.Current);
Iterator.GotoNext();
end;
Iterator.Free();
Result := CreateXmlResponse();
end;
function TControlWebSiteRequestHandler.HandleRequest(): THttpResponse;
begin
if (Request.HttpRequest.RequestLine.Method = THttpMethod.Post) and (Request.HttpRequest.Entity.ContentType is TMediaTypeApplicationXml) then
Result := HandleXmlRequest()
else
begin
if Request.GetParameters.KeyExists('format') and (Request.GetParameters.GetTextValue('format') = 'PDF') then
Result := RenderToPdf()
else
begin
if Request.GetParameters.KeyExists('timestamp') then
Result := RenderToImage()
else
Result := RenderToHtml();
end;
end;
end;
function TControlWebSiteRequestHandler.HandleSetEditingRequest(Element: TDomElement): THttpXmlResponse;
begin
if Element.Attributes.Get('enabled').AsBoolean() then
Control.Mode := TControlMode.Edit
else
Control.Mode := TControlMode.Display;
Result := CreateXmlResponse();
end;
function TControlWebSiteRequestHandler.HandleXmlRequest(): THttpResponse;
var
Element: TDomElement;
InputStream: TInputStream;
begin
Window.Invalidated := False;
InputStream := Request.HttpRequest.Entity.Content.CreateInputStream();
Element := ParseXmlToDom(InputStream);
if Element.Name = 'events' then
Result := HandleEventRequest(Element)
else if Element.Name = 'setEditing' then
Result := HandleSetEditingRequest(Element)
else
raise EException.Create('Unknown command: ' + Element.Name);
InputStream.Free();
Element.Free();
end;
function TControlWebSiteRequestHandler.HtmlToText(Element: THtmlElement): TText;
var
Writer: THtmlDocumentWriter;
TextStream: TTextOutputStream;
begin
TextStream := TTextOutputStream.Create(TCharacterEncoding.Windows1252, 1024);
Writer := THtmlDocumentWriter.Create(TXmlWriter.Create(TextStream, TCharacterEncoding.Windows1252));
Writer.WriteElement(Element);
Result := TextStream.GetValue();
Writer.Free();
TextStream.Free();
end;
function TControlWebSiteRequestHandler.LinkToControl(): THtmlDivision;
var
ControlImage: THtmlImage;
FocusedObject: THtmlDivision;
Hint: THtmlDivision;
Script: THtmlScript;
DownloadAs: TMenuItem;
Pdf: TMenuItem;
Menu: TMenuItem;
ContainerMenu: TMenuItem;
MenuControl: TWebSiteMenuControl;
EffectiveUri: TUri;
begin
EffectiveUri := GetEffectiveUri();
ControlImage := THtmlImage.Create();
ControlImage.Size := Window.Size;
ControlImage.Source := EffectiveUri;
ControlImage.Source.Parameters.Add('timestamp', GetTickCount());
Result := THtmlDivision.Create();
Result.Classes.Add('control');
Result.Classes.Add('hasMenu');
Result.Contents.Add(ControlImage);
Pdf := TMenuItem.Create();
Pdf.Caption := tmPdf;
Pdf.Target := EffectiveUri;
Pdf.Target.Parameters.Add('format', 'PDF');
DownloadAs := TMenuItem.Create();
DownloadAs.Caption := tmDownloadAs;
DownloadAs.ChildItems.Add(Pdf);
Menu := TMenuItem.Create();
Menu.ChildItems.Add(DownloadAs);
ContainerMenu := TMenuItem.Create();
ContainerMenu.ChildItems.Add(Menu);
MenuControl := TWebSiteMenuControl.Create(ContainerMenu);
Result.Contents.Add(MenuControl.Render(Request.Translator, Request.Session.MenuItems));
MenuControl.Free();
ContainerMenu.Free();
FocusedObject := THtmlDivision.Create();
FocusedObject.Classes.Add('focusedObject');
Result.Contents.Add(FocusedObject);
Hint := THtmlDivision.Create();
Hint.Classes.Add('hint');
Result.Contents.Add(Hint);
Script := THtmlScript.Create();
Script.ScriptType := stTextJavascript;
Script.Lines.Add('var control = new Control();');
if TControlMode.Edit in Control.AllowedModes then
Script.Lines.Add('control.addEditMenuOption("' + Request.Localizer.Text.Translate(tmEdit) + '", ' + JavascriptBoolean(Control.Mode = TControlMode.Edit) + ');');
Result.Contents.Add(Script);
end;
function TControlWebSiteRequestHandler.RenderToRasterImage(): TRasterImage;
var
Canvas: TGdiCanvas;
Bitmap: TGdiBitmap;
begin
Bitmap := TGdiBitmap.Create(Window.Size);
Canvas := TGdiCanvas.Create();
Canvas.DeviceContext := Bitmap.DeviceContext;
Canvas.Fill := TFill.Create(TNamedColor.White);
Canvas.FillRectangle(Window.Size);
Window.PaintAll(Canvas);
Result := Bitmap.ConvertToRasterImage();
Canvas.Free();
Bitmap.Free();
end;
procedure TControlWebSiteRequestHandler.SetTitle(const Value: TDocumentLocalize);
begin
if Value <> Title then
begin
Value.AddReference();
Title.ReleaseReference();
FTitle := Value;
end;
end;
function TControlWebSiteRequestHandler.TableModelToText(TableModel: TTableModel): TText;
var
Size: TInteger32Size;
Cells: TTableCells;
Columns: TTableHeaders;
Row: TTableRow;
HtmlTable: THtmlTable;
HtmlRow: THtmlTableRow;
i: TInteger32;
j: TInteger32;
begin
Size := TableModel.GetSize();
Cells := TableModel.GetCells(Size);
Columns := TableModel.GetColumnModel().GetHeaders(TInteger32Interval.NewFromSize(Size.Width));
HtmlTable := THtmlTable.Create();
HtmlTable.AddReference();
HtmlRow := THtmlTableRow.Create();
for i := Columns.Range.Low to Columns.Range.High do
HtmlRow.Cells.Add(TableHeaderTextCell(TDocumentToTextCompiler.RenderToText(Request.Translator, Columns[i].Caption)));
HtmlTable.Header.Add(HtmlRow);
for i := 0 to Cells.Bounds.Height - 1 do
begin
Row := Cells.Rows[i];
HtmlRow := THtmlTableRow.Create();
for j := 0 to Row.ColumnCount - 1 do
HtmlRow.Cells.Add(TableTextCell(Row[j].Value.ToText()));
HtmlTable.Body.Add(HtmlRow);
end;
Result := HtmlToText(HtmlTable);
HtmlTable.ReleaseReference();
Columns.Free();
Cells.Free();
end;
function TControlWebSiteRequestHandler.RenderToHtml(): THttpHtmlResponse;
begin
Result := THttpHtmlResponse.Create();
Result.Element := LinkToControl();
end;
function TControlWebSiteRequestHandler.RenderToImage(): THttpResponse;
var
Stream: TOutputStream;
Writer: TPortableNetworkGraphicsWriter;
Image: TRasterImage;
begin
Image := RenderToRasterImage();
Image.AddReference();
Result := THttpResponse.Create();
Result.Entity.ContentType := TMediaTypeImagePng.Create();
Stream := Result.Entity.Content.CreateAppendStream();
Writer := TPortableNetworkGraphicsWriter.Create(Stream);
Writer.Write(Image);
Writer.Free();
Stream.Free();
Image.ReleaseReference();
end;
function TControlWebSiteRequestHandler.RenderToPdf(): THttpPdfResponse;
var
Margin: TInteger32;
ScaleFactor: TFloatingPoint64;
Builder: TPdfDocumentBuilder;
Canvas: TPdfCanvas;
Page: TPdfPage;
Matrix: T2dAffineTransformation;
begin
Builder := TPdfDocumentBuilder.Create();
Page := Builder.PageFactory.AddPage();
Margin := 50;
ScaleFactor := (Page.Size.Width - 2 * Margin) / Control.Width;
Matrix := T2dAffineTransformation.Create();
Matrix.Translate := T2dFloatingPoint64Point.New(Margin, Page.Size.Height - Margin);
Matrix.ScaleX := ScaleFactor;
Matrix.ScaleY := ScaleFactor;
Page.Instructions.Add(TPdfUserTransformationInstruction.Create(Matrix));
Canvas := TPdfCanvas.Create(Page.Instructions, Builder.Fonts);
Control.Paint(Canvas);
Canvas.Free();
Result := THttpPdfResponse.Create();
Result.Document := Builder.Document;
Builder.Free();
end;
end.
|