| 1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
| ///////////////////////////////////////////////////////////////////////////
// //
// Copyright (c) 2015 by Charta Software B.V. //
// All rights reserved //
// //
// Version: 1.7.0.83525 //
// Web site: https://pascal.chartasoftware.com/ //
// //
// This code and information are provided "as is" without warranty of //
// any kind. Dissemination of this information or reproduction of //
// this material is strictly forbidden unless prior written permission //
// is obtained from Charta Software B.V.. //
// //
///////////////////////////////////////////////////////////////////////////
unit WebSite.Session;
interface
{$SCOPEDENUMS ON}
uses
Authorization.RightsMode,
Boolean,
Collection.Map,
DateTime.Calendar.Gregorian.Date.Period,
DateTime.Localizer,
DateTime.TickCount,
Dom.Element,
Integer._32,
Integer._32.Positive,
Projector,
Sql.Database,
StructuredDocument.Node.Localize,
Text,
Thread.Lock,
UserManagement.User,
Uuid,
WebSite.InterfaceType,
WebSite.Menu.Item.Session,
WebSite.Preferences;
type
TInteractionMode = (Presentation, Normal);
TScreenMode = (Normal, Maximized);
TSessionState = (New, LoggedIn, LoggedOut);
TDisplayMode = (WebSite, Desktop);
TDisplayModePerInterface = array [TWebSiteInterfaceType] of TDisplayMode;
TWebSiteSessionSetting = class(TObject)
public
function GetIdentifier(): TText; virtual; abstract;
procedure Load(Element: TDomElement); virtual; abstract;
procedure Save(Element: TDomElement); virtual; abstract;
end;
TWebSiteSession = class(TObject)
private
FUser: TUser;
FSelectedPeriod: TGregorianDatePeriod;
FModuleStorage: TMap<TText, TDomElement>;
procedure SetUser(const Value: TUser);
procedure SetSelectedPeriod(const Value: TGregorianDatePeriod);
private
Settings: TMap<TText, TDomElement>;
public
Lock: TThreadLock;
LogoutPeriod__s: TPositiveInteger32;
LastAccessTickCount: TTickCount;
Identifier: TUuid;
SerialIdentifier: TInteger32;
Preferences: TWebSitePreferences;
DisplayMode: TDisplayModePerInterface;
ScreenMode: TScreenMode;
InteractionMode: TInteractionMode;
MenuItems: TSessionMenuItems;
RightsMode: TRightsMode;
TimeLocalizer: TTimeLocalizer;
State: TSessionState;
ClearFormsByDefault: TBoolean;
SupportsImpersonate: TBoolean;
constructor Create(); virtual;
destructor Destroy(); override;
procedure Load(Database: TSqlDatabase);
procedure Save(Database: TSqlDatabase);
procedure LoadSetting(Setting: TWebSiteSessionSetting);
procedure SaveSetting(Setting: TWebSiteSessionSetting);
function LoggedIn(): TBoolean;
function AdministratorLoggedIn(Database: TSqlDatabase): TBoolean;
function LogIn(Database: TSqlDatabase; const Email: TText; const Password: TText): TBoolean; overload;
function LogIn(Database: TSqlDatabase; UserIdentifier: TInteger32): TBoolean; overload;
function LogInAsApplication(Database: TSqlDatabase; const Bearer: TText): TBoolean;
procedure LogOut();
procedure LogOutIfExpired(CurrentTickCount: TTickCount);
function HasAdministratorRights(Database: TSqlDatabase): TBoolean;
function HasImpersonationRights(Database: TSqlDatabase): TBoolean;
property ModuleStorage: TMap<TText, TDomElement> read FModuleStorage;
property User: TUser read FUser write SetUser;
property SelectedPeriod: TGregorianDatePeriod read FSelectedPeriod write SetSelectedPeriod;
public
type
TKey = class(TProjector<TWebSiteSession, TUuid>)
public
function Project(const Session: TWebSiteSession): TUuid; override;
public
class var
Instance: TKey;
class constructor Create();
class destructor Destroy();
end;
end;
function TextToDisplayMode(const Value: TText): TDisplayMode;
function TextToScreenMode(const Value: TText): TScreenMode;
function TextToRightsMode(const Value: TText): TRightsMode;
function DisplayModeToText(Value: TDisplayMode): TText;
function ScreenModeToText(Value: TScreenMode): TText;
function RightsModeToText(Value: TRightsMode): TText;
function DisplayModeToTranslationMap(Value: TDisplayMode): TDocumentLocalize;
implementation
uses
DateTime.Zone,
Exception,
Language.TranslationMap.Constants,
Language.TranslationMap.Constants.General,
Object_.Reference.Owner,
Sql,
Sql.Builder,
Sql.Expression,
Sql.Functions.DateTime,
Sql.Literal,
Sql.Result,
Text.Map.Hash,
UserManagement.Table.Set_,
WebSite.Session.Table.Set_;
function TextToDisplayMode(const Value: TText): TDisplayMode;
begin
if Value = 'WebSite' then
Result := TDisplayMode.WebSite
else if Value = 'Desktop' then
Result := TDisplayMode.Desktop
else
raise EException.Create('Unknown display mode: ' + Value);
end;
function TextToScreenMode(const Value: TText): TScreenMode;
begin
if Value = 'Maximize' then
Result := TScreenMode.Maximized
else if Value = 'Normal' then
Result := TScreenMode.Normal
else
raise EException.Create('Unknown screen mode: ' + Value);
end;
function TextToRightsMode(const Value: TText): TRightsMode;
begin
if Value = 'All' then
Result := rmAll
else if Value = 'Restricted' then
Result := rmRestricted
else
raise EException.Create('Unknown rights mode: ' + Value);
end;
function DisplayModeToText(Value: TDisplayMode): TText;
begin
case Value of
TDisplayMode.WebSite:
Result := 'WebSite';
TDisplayMode.Desktop:
Result := 'Desktop';
else
raise EException.Create('Unknown display mode');
end;
end;
function ScreenModeToText(Value: TScreenMode): TText;
begin
case Value of
TScreenMode.Maximized:
Result := 'Maximize';
TScreenMode.Normal:
Result := 'Normal';
else
raise EException.Create('Unknown screen mode');
end;
end;
function RightsModeToText(Value: TRightsMode): TText;
begin
case Value of
rmAll:
Result := 'All';
rmRestricted:
Result := 'Restricted';
else
raise EException.Create('Unknown rights mode');
end;
end;
function DisplayModeToTranslationMap(Value: TDisplayMode): TDocumentLocalize;
begin
case Value of
TDisplayMode.WebSite:
Result := tmWebSite;
TDisplayMode.Desktop:
Result := tmDesktop;
else
raise EException.Create('Unknown display mode');
end;
end;
{ TWebSiteSession }
function TWebSiteSession.AdministratorLoggedIn(Database: TSqlDatabase): TBoolean;
begin
Result :=
LoggedIn()
and Database.Exists(
Select(
[ UserManagementTableSet.AdministratorsTable.UserID ],
[ UserManagementTableSet.AdministratorsTable ],
[ UserManagementTableSet.AdministratorsTable.UserID = User.Id ]
)
);
end;
constructor TWebSiteSession.Create();
begin
inherited Create();
Identifier := TUuid.Unknown;
Lock := TThreadLock.Create();
MenuItems := TSessionMenuItems.Create();
Preferences := TWebSitePreferences.Create();
State := TSessionState.New;
SupportsImpersonate := True;
TimeLocalizer := TTimeLocalizer.Create();
TimeLocalizer.SelectedZone := TTimeZone.Utc;
FModuleStorage := TTextHashMap<TDomElement>.Create();
FModuleStorage.ValueManager := TReferenceOwner<TDomElement>.Create();
Settings := TTextHashMap<TDomElement>.Create();
Settings.ValueManager := TReferenceOwner<TDomElement>.Create();
end;
destructor TWebSiteSession.Destroy();
begin
Lock.Free();
ModuleStorage.Free();
Preferences.Free();
MenuItems.Free();
User.Free();
TimeLocalizer.Free();
SelectedPeriod.ReleaseReference();
Settings.Free();
inherited Destroy();
end;
function TWebSiteSession.HasAdministratorRights(Database: TSqlDatabase): TBoolean;
begin
Result := (RightsMode = rmAll) and AdministratorLoggedIn(Database);
end;
function TWebSiteSession.HasImpersonationRights(Database: TSqlDatabase): TBoolean;
begin
Result := SupportsImpersonate and HasAdministratorRights(Database);
end;
procedure TWebSiteSession.Load(Database: TSqlDatabase);
var
SqlResult: TSqlResult;
begin
Lock.Acquire();
try
Database.Query(
Update(
[ WebSiteSessionTableSet.SessionsTable ],
[ Assign(WebSiteSessionTableSet.SessionsTable.UserId, Null) ],
[
WebSiteSessionTableSet.SessionsTable.Uuid = Deprecated_LiteralTexualUuid(Identifier),
TimestampDifference(stuSecond, WebSiteSessionTableSet.SessionsTable.TimeLastUsed, Sql.Now()) > LogoutPeriod__s
]
)
);
SqlResult := Database.QuerySingleRow(
Select(
[ WebSiteSessionTableSet.SessionsTable.UserId ],
[ WebSiteSessionTableSet.SessionsTable ],
[ WebSiteSessionTableSet.SessionsTable.Uuid = Deprecated_LiteralTexualUuid(Identifier) ]
)
);
if not SqlResult.ReadNull() then
Login(Database, SqlResult.ReadInteger());
SqlResult.Free();
finally
Lock.Release();
end;
end;
procedure TWebSiteSession.LoadSetting(Setting: TWebSiteSessionSetting);
var
Element: TDomElement;
begin
Lock.Acquire();
try
Element := Settings[Setting.GetIdentifier()];
if Element <> nil then
Setting.Load(Element);
finally
Lock.Release();
end;
end;
function TWebSiteSession.LoggedIn(): TBoolean;
begin
Result := User <> nil;
end;
function TWebSiteSession.LogIn(Database: TSqlDatabase; UserIdentifier: TInteger32): TBoolean;
begin
User := TUser.LoadWithIdentifier(Database, UserIdentifier);
Result := LoggedIn;
end;
function TWebSiteSession.LogInAsApplication(Database: TSqlDatabase; const Bearer: TText): TBoolean;
var
NewUser: TUser;
Uuid: TUuid;
begin
Uuid := TUuid.FromText(Bearer);
NewUser := TUser.LoadWithBearer(Database, Uuid);
Result := (NewUser <> nil) and (NewUser.ActivatedInstant <> nil);
if Result then
begin
User := NewUser;
State := TSessionState.LoggedIn;
end
else
NewUser.Free();
end;
function TWebSiteSession.LogIn(Database: TSqlDatabase; const Email: TText; const Password: TText): TBoolean;
var
NewUser: TUser;
begin
NewUser := TUser.LoadWithEMail(Database, EMail);
Result := (NewUser <> nil) and NewUser.CheckEMailActivated(Password);
if Result then
begin
User := NewUser;
State := TSessionState.LoggedIn;
end
else
NewUser.Free();
end;
procedure TWebSiteSession.LogOut();
begin
User := nil;
State := TSessionState.LoggedOut;
end;
procedure TWebSiteSession.LogOutIfExpired(CurrentTickCount: TTickCount);
begin
if LoggedIn and LastAccessTickCount.PeriodHasExpired(CurrentTickCount, 1000 * LogoutPeriod__s) then
Logout();
end;
procedure TWebSiteSession.Save(Database: TSqlDatabase);
var
UserId: TSqlExpressionBuilder;
begin
Lock.Acquire();
try
if User <> nil then
UserId := TSqlLiteralInteger.Create(User.Id)
else
UserId := TSqlNull.Create();
Database.Query(
Update(
[ WebSiteSessionTableSet.SessionsTable ],
[
Assign(WebSiteSessionTableSet.SessionsTable.TimeLastUsed, Sql.Now()),
Assign(WebSiteSessionTableSet.SessionsTable.UserId, UserId)
],
[ WebSiteSessionTableSet.SessionsTable.Uuid = Deprecated_LiteralTexualUuid(Identifier) ]
)
);
finally
Lock.Release();
end;
end;
procedure TWebSiteSession.SaveSetting(Setting: TWebSiteSessionSetting);
var
Identifier: TText;
Element: TDomElement;
begin
Lock.Acquire();
try
Identifier := Setting.GetIdentifier();
Element := Settings[Identifier];
if Element = nil then
begin
Element := TDomElement.Create(Identifier);
Settings[Identifier] := Element;
end;
Setting.Save(Element);
finally
Lock.Release();
end;
end;
procedure TWebSiteSession.SetSelectedPeriod(const Value: TGregorianDatePeriod);
begin
if Value <> SelectedPeriod then
begin
Value.AddReference();
SelectedPeriod.ReleaseReference();
FSelectedPeriod := Value;
end;
end;
procedure TWebSiteSession.SetUser(const Value: TUser);
begin
if Value <> User then
begin
User.Free();
FUser := Value;
end;
end;
{ TWebSiteSession.TKey }
class destructor TWebSiteSession.TKey.Destroy();
begin
Instance.ReleaseReference();
end;
class constructor TWebSiteSession.TKey.Create();
begin
Instance := TKey.Create();
Instance.AddReference();
end;
function TWebSiteSession.TKey.Project(const Session: TWebSiteSession): TUuid;
begin
Result := Session.Identifier;
end;
end.
|